Comment manipuler la base de registre Windows en Perl ?

Si comme moi vous êtes sous Windows (Vista en ce qui me concerne) et utilisez ActivePerl, vous avez certaines informations d'ActivePerl dans votre base de registre suite à son installation que nous allons lister :

• lieu de location ;
• date d'installation ;
• version ;
• …

Les informations d'installation des logiciels sous Windows se trouvent dans la base de registre à ce niveau : HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/Windows/CurrentVersion/Uninstall.

Sous certains postes comme Windows Seven 64 bits, le chemin peut être : HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\. Pour en savoir plus, lisez cette note Microsoft : 32-bit and 64-bit Application Data in the registry.

Ensuite, dans le niveau du dessous, vous avez le nom du logiciel ou un code. Il va donc falloir parcourir la liste des noms et pour chacun d'eux, on recherche une clé se nommant « DisplayName ». Cela permet de s'assurer qu'il s'agit bien du logiciel recherché. Voici une capture d'écran montrant les informations à trouver et un programme pour rechercher les informations sur ActivePerl.

ActivePerl : base de registre

Sélectionnez

1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.
20.
21.
22.
23.
24.
25.
26.
27.
28.
29.
30.
31.
32.
33.
34.
35.
36.
37.
38.
39.
40.
41.
42.
43.
44.

#!/usr/bin/perl
use strict;
use warnings;
use Win32::TieRegistry;

my $nom_logiciel = 'ActivePerl';
if ( my $RefInfoPerl = GetProductCode($nom_logiciel) ) {
  foreach my $cle ( keys %{$RefInfoPerl} ) {
    print "$cle : $RefInfoPerl->{$cle}\n";
  }
}

sub GetProductCode {
  my $Name         = shift;
  my $RegistryPath = 'HKEY_LOCAL_MACHINE/SOFTWARE/Microsoft/Windows/CurrentVersion/Uninstall';
  my %InfoProduct;

  $Registry->Delimiter('/');

  my $SubKey = $Registry->{$RegistryPath} or die "Lecture impossible : $RegistryPath\n$^E\n";

  foreach my $key ( keys %{$SubKey} ) {
    my $RefName = $SubKey->{$key}{DisplayName};

    if ( $RefName and $RefName =~ m{$Name}i ) {
      $InfoProduct{Code} = $key;
      if ( exists $SubKey->{$key}{DisplayName} ) {
        $InfoProduct{DisplayName} = $SubKey->{$key}{DisplayName};
      }
      if ( exists $SubKey->{$key}{InstallLocation} ) {
        $InfoProduct{InstallLocation} = $SubKey->{$key}{InstallLocation};
      }
      if ( exists $SubKey->{$key}{DisplayVersion} ) {
        $InfoProduct{DisplayVersion} = $SubKey->{$key}{DisplayVersion};
      }
      if ( exists $SubKey->{$key}{InstallDate} ) {
        $InfoProduct{InstallDate} = $SubKey->{$key}{InstallDate};
      }
      last;
    }
  }

  return \%InfoProduct;
}

J'obtiens sur mon ordinateur le résultat suivant :

Code : {02BFF1A3-A0D5-4F64-8558-A22682BCDA58}/
DisplayVersion : 5.14.1402
InstallDate : 20111124
DisplayName : ActivePerl 5.14.2 Build 1402
InstallLocation : C:\Perl\

Le programme contient une procédure nommée « GetProductcode » qui nous permet de lister certaines informations. Le nom de logiciel que nous cherchons est passé en argument. Dans le cas ci-dessus, c'est « ActivePerl », mais ça aurait pu être Adobe, Gimp… 

En ligne 15, la variable contient le chemin dans la base de registre qui permet d'accéder à la plupart des logiciels installés. Les données récupérées sont stockées dans un hash qui est renvoyé par la procédure.

En ligne 18, nous précisons que le délimiteur est un slash « / ».

La ligne 20 permet de récupérer la base de registre au niveau de l'arborescence voulue. Ensuite, on parcourt ce hash pour extraire ce dont on a besoin.
N.B. La variable est une référence de hash.

En ligne 23, on récupère la valeur de la clé « DisplayName », ce qui nous permet de trouver réellement notre logiciel. Une fois trouvé, nous récupérons les valeurs des clés « InstallLocation », « DisplayVersion », et « InstallDate ». Exemple :

      if ( exists $SubKey->{$key}{InstallLocation} ) {
        $InfoProduct{InstallLocation} = $SubKey->{$key}{InstallLocation};
      }

Comme vous pouvez le constater, c'est très simple. Le plus compliqué, c'est de connaître un peu l'arborescence de la base de registre pour savoir où chercher. Nous aurions pu écrire notre code différemment. Si vous voulez en savoir plus, lisez la documentation du module Win32::TieRegistryModule CPAN Win32::TieRegistry.

Nous souhaitons travailler sur les extensions de type « .dvp ». Créons une clé .dvp dans l'HKEY « HKEY_CLASSES_ROOT ». À l'intérieur, attribuons à la clé « par défaut » une valeur de notre choix : FichierDVP.

Il est important de choisir un nom sans espace.

Pour créer la clé .dvp, vous faites un clic droit sur HKEY_CLASSES_ROOT, puis Nouveau → Clé.

Maintenant, il faut créer une clé du même nom choisi ci-dessus « FichierDVP » dans laquelle on crée deux clés :

• Une sous-clé « DefaultIcon ». Sa valeur par défaut aura le nom du fichier developpez.ico (chemin complet), c'est cette icône qui sera affichée dans l'explorateur Windows pour tous les fichiers d'extension .dvp. Pour l'article, l'icône se trouve dans le répertoire Temp : C:\Temp\developpez.ico. Nous aurions pu indiquer le nom d'un fichier .exe ou .dll suivi d'une virgule et du rang de l'icône voulue dans ce fichier (0, 1, 2… ) ;
• Une sous-clé « shell » pour action dans laquelle on crée une sous-clé « open », puis à l'intérieur une sous-clé « command ». Sa valeur par défaut contient la commande à exécuter (Notepad++). Dans la commande, on précisera l'argument %1 qui contient le nom du fichier. Pensez aux guillemets afin d'éviter les mauvaises surprises des noms de fichiers avec espaces.
  On aura donc shell → open → command et « C:\Program Files\Notepad++\notepad++.exe "%1" » en commande.

À ce stade, tout double-clic sur un fichier d'extension « .dvp » lancera Notepad++ avec en argument le nom du fichier. Le fichier sera ainsi ouvert dans Notepad++.
Pour voir vos fichiers .dvp avec l'icône dvp, vous devez redémarrer votre ordinateur ou au moins, fermer et relancer votre session.

Voyons maintenant comment faire cette modification de la base de registre en Perl.

Programme de création des clés

Sélectionnez

1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.
20.
21.
22.
23.
24.
25.
26.
27.
28.
29.
30.
31.
32.
33.
34.

#!/usr/bin/perl
use strict;
use warnings;
use Win32::TieRegistry;

$Registry->Delimiter('/');
my $NomExtension = 'FichierDVP';

# Suppression des clés si présentes
$Registry->FastDelete(1);
delete $Registry->{"HKEY_CLASSES_ROOT/$NomExtension/DefaultIcon/"};
delete $Registry->{"HKEY_CLASSES_ROOT/$NomExtension/shell/open/command/"};
delete $Registry->{"HKEY_CLASSES_ROOT/$NomExtension/shell/open/"};
delete $Registry->{"HKEY_CLASSES_ROOT/$NomExtension/shell/"};
delete $Registry->{"HKEY_CLASSES_ROOT/$NomExtension/"};
delete $Registry->{"HKEY_CLASSES_ROOT/.dvp/"};

# Création des nouvelles clés
# Clé .dvp
$Registry->{"HKEY_CLASSES_ROOT/.dvp/"} = { '/' => $NomExtension };

# Clé FichierDVP
$Registry->{"HKEY_CLASSES_ROOT/$NomExtension/"} = {
    'DefaultIcon' => {
        '/' => 'C:\Temp\developpez.ico',
    },
    'shell' => {
        'open' => {
            'command' => {
                '/' => 'C:\Program Files\Notepad++\notepad++.exe "%1"'    
            }    
        },
    }
};

La ligne 6 permet de définir le délimiteur.
La ligne 7 définit la variable qui contient le nom de notre nouvelle extension.

IV-B-1. Suppression des clés▲

$ref_copie = delete $Registry->{"HKEY_CLASSES_ROOT/.dvp/"};

IV-B-2. Création des clés▲

'DefaultIcon' => {
        '/' => 'C:\Temp\developpez.ico',
},

'DefaultIcon' => {
        '' => 'C:\Temp\developpez.ico',
},