Services à superviser avec Nagios

root@supervision:~# /usr/local/nagios/libexec/check_nt -H SERVEURWINDOWS -v USEDDISKSPACE -s MOTDEPASSE -p 12489 -l C -w 80 -c 90 -u GB
C:\ - total: 30,01 Gb - utilisé: 19,75 Gb (66%) - libre 10,25 Gb (34%) | 'C:\ Espace Utilisé'=19,75Gb;24,00;27,01;0.00;30,01

# Espace disque

define service{
    use            generic-service
    host_name        SERVEURWINDOWS
    service_description    C:\ Espace Disque
    check_command        check_nt!USEDDISKSPACE!-l c -w 80 -c 90 -u GB
    }

root@supervision:/usr/local/nagios/etc#/usr/local/nagios/libexec/check_nrpe -H SERVEURLINUX -c check_disk -a 20% 10% /
DISK OK - free space: / 38858 MB (84% inode=94%);| /=6993MB;38644;43474;0;48305

# Vérification de l'espace disque
define service{
    use                         generic-service
    host_name                     SERVEURLINUX
    service_description           Espace disque /
    check_command               check_nrpe!check_disk!20%!10%!/
    }

# Charge CPU

define service{
    use            generic-service
    host_name        SERVEURWINDOWS
    service_description    CPU Load
    check_command        check_nt!CPULOAD!-l 5,80,90
    }

# Vérification de la charge CPU

define service{
    use                     generic-service
    host_name               SERVEURLINUX
    service_description     Charge CPU
    check_command           check_nrpe!check_load!0.7,0.6,0.5!0.9,0.8,0.7
    }

root@supervision:# /usr/local/nagios/libexec/check_nt -H SERVEURWINDOWS -v MEMUSE -s MOTDEPASSE -p 12489 -w 80 -c 90
Mémoire utilisée: total:2168,51 Mb - utilisée: 466,13 Mb (21%) - libre: 1702,39 Mb (79%) | 'Mémoire utilisée'=466,13Mb;0,00;0,00;0.00;2168,51

# Mémoire RAM

define service{
    use            generic-service
    host_name        SERVEURWINDOWS
    service_description    Mémoire utilisée
    check_command        check_nt!MEMUSE!-w 80 -c 90
    }

#!/usr/bin/perl
#===============================================================================
# Auteur : djibril
# Date   : 29/10/2013
# But    : Check Memory and Swap on Linux/Unix
#===============================================================================
use strict;
use warnings;

use Monitoring::Plugin;
use English '-no_match_vars';
use Sys::MemInfo qw/availkeys/;
use vars qw/ $VERSION /;

# Version du plugin
$VERSION = '1.0';

my $LICENCE = 'This Plugin is free';

my $plugin_nagios = Monitoring::Plugin->new(
    shortname => 'Check memory',
    usage     => 'Usage : %s [ -c|--critical=<threshold> ] [ -w|--warning=<threshold> ] [ -M|--memory=<mem or swap> ]',
    version   => $VERSION,
    license   => $LICENCE,
);

if ( lc $OSNAME eq 'mswin32' ) {
    $plugin_nagios->plugin_exit( CRITICAL, "[Win32] This plugin does not work for this plateform\n" );
}

# Activer gestion mémoire swap
$plugin_nagios->add_arg(
    spec     => 'memory|M=s',
    help     => 'type of memory : swap or mem',
    required => 1,
);

# Définition de l'argument warning
$plugin_nagios->add_arg(
    spec     => 'warning|w=f',                                               # Nous acceptons des nombres réels
    help     => 'Exit with WARNING status if more than pourcentage',
    required => 1,
);

# Définition de l'argument critical
$plugin_nagios->add_arg(
    spec     => 'critical|c=f',
    help     => 'Exit with CRITICAL status if more than pourcentage',
    required => 1,
);

# Activer le parsing des options de ligne de commande
$plugin_nagios->getopts;
my %memory = map { $_ => Sys::MemInfo::get($_) } availkeys();

my $percent_memory_used = $plugin_nagios->opts->memory eq 'swap' ? sprintf '%.2f', (($memory{totalswap} - $memory{freeswap})/$memory{totalswap}) * 100 
    : sprintf '%.2f', (($memory{totalmem} - $memory{freemem})/$memory{totalmem}) * 100
    ;

my $message_memory = $plugin_nagios->opts->memory eq 'swap' ? 
      'Total Memory Swap : ' . sprintf('%.2f',($memory{totalswap}/(1024*1024))) . 'MB - Swap used : ' . $percent_memory_used . '%'
    : 'Total Memory : ' . sprintf('%.2f',($memory{totalmem}/(1024*1024))) . 'MB - Mem used : ' . $percent_memory_used . '%'
    ;
if ( $plugin_nagios->opts->verbose ) {
    while ( my ($key, $value) = each %memory ) {
        print "$key : $value\n";
    }
}

my $code_retour = $plugin_nagios->check_threshold(
    check    => $percent_memory_used,
    warning  => $plugin_nagios->opts->warning,
    critical => $plugin_nagios->opts->critical,
);

$plugin_nagios->plugin_exit( $code_retour, $message_memory );

chmod +x check_memory.pl

cpan -i Monitoring::Plugin Sys::MemInfo

# /usr/local/nagios/libexec/check_memory.pl -v -w 85 -c 95 -M mem
totalmem : 2124271616
freeswap : 2221649920
totalswap : 2222977024
freemem : 354693120
Check memory OK - Total Memory : 2025.86MB - Mem used : 83.30%

# /usr/local/nagios/libexec/check_memory.pl -w 10 -c 20 -M swap
Check memory OK - Total Memory Swap : 2120.00MB - Swap used : 0.06%

# vi /usr/local/nagios/etc/nrpe.cfg
…
…
command[check_memory]=/usr/local/nagios/libexec/check_memory.pl -w $ARG1$ -c $ARG2$ -M $ARG3$

# /usr/local/nagios/libexec/check_nrpe -H 127.0.0.1 -c check_memory -a 80 90 swap
Check memory OK - Total Memory Swap : 2120.00MB - Swap used : 0.06%

root@supervision:~# /usr/local/nagios/libexec/check_nrpe -H SERVEURLINUX -c check_memory -a 80 90 mem
Check memory WARNING - Total Memory : 2025.86MB - Mem used : 82.73%

# Mémoire RAM

define service{
    use                     generic-service
    host_name               SERVEURLINUX
    service_description     Mémoire RAM
    check_command           check_nrpe!check_memory!90!95!mem
    }

# SWAP

define service{
    use                     generic-service
    host_name               SERVEURLINUX
    service_description     Mémoire Swap
    check_command           check_nrpe!check_memory!10!20!swap
    }

;allow_arguments=0

allow_arguments=1

root@supervision:~# /usr/local/nagios/libexec/check_nt -H SERVEURWINDOWS -v UPTIME -p 12489 -s MOTDEPASSE
Système démarré - 9 jour(s) 5 heure(s) 10 minute(s)

root@supervision:~# /usr/local/nagios/libexec/check_nrpe -H SERVEURWINDOWS -c CheckUpTime -a MaxCrit=10d MaxWarn=8d
WARNING: uptime: 1w 2d 5:28 > warning|'uptime'=797289000;777600000;864000000

# Temps de fonctionnement du système

define service{
 use            generic-service
 host_name        SERVEURWINDOWS
 service_description    Vérification Uptime
 check_command        check_nrpe!CheckUpTime!MaxCrit=60d MaxWarn=30d
 }

#!/usr/bin/perl
#===============================================================================
# Auteur : djibril
# Date   : 31/10/2013
# But    : Check Uptime on Linux/Unix
#===============================================================================
use strict;
use warnings;

use Monitoring::Plugin;
use English '-no_match_vars';
use vars qw/ $VERSION /;

# Version du plugin
$VERSION = '1.0';

my $LICENCE = 'This Plugin is free';

my $plugin_nagios = Monitoring::Plugin->new(
    shortname => 'Check uptime',
    usage     => 'Usage : %s [ -c|--critical=<threshold> ] [ -w|--warning=<threshold> ]',
    version   => $VERSION,
    license   => $LICENCE,
);

if ( lc $OSNAME eq 'mswin32' ) {
    $plugin_nagios->plugin_exit( CRITICAL, "[Win32] This plugin does not work for this plateform\n" );
}

# Définition de l'argument warning
$plugin_nagios->add_arg(
    spec     => 'warning|w=f',
    help     => 'Exit with WARNING status if more than x days',
    label    => 'Days',
    required => 0,
);

# Définition de l'argument critical
$plugin_nagios->add_arg(
    spec     => 'critical|c=f',
    help     => 'Exit with CRITICAL status if more than x days',
    label    => 'Days',
    required => 0,
);

# Activer le parsing des options de ligne de commande
$plugin_nagios->getopts;

my $uptime_linux = uptime();

if ( !$uptime_linux ) {
    $plugin_nagios->plugin_exit( CRITICAL, "unable to get uptime\n" );
}

my $seuil_warning  = $plugin_nagios->opts->warning ? $plugin_nagios->opts->warning * 60 * 60 * 24 : undef;
my $seuil_critical = $plugin_nagios->opts->critical ? $plugin_nagios->opts->critical * 60 * 60 * 24 : undef;
if ( $plugin_nagios->opts->verbose ) {
    print "Uptime : $uptime_linux\n";
    if ( defined $seuil_warning ) {
        print 'WARNING threshold : ', $seuil_warning, 
            ' (', time_format( $seuil_warning ), ')', "\n";
    }
    if ( defined $seuil_critical ) {
        print 'CRITICAL threshold : ', $seuil_critical, 
            '( ', time_format( $seuil_critical ), ')', "\n";
    }

}

my $code_retour = $plugin_nagios->check_threshold(
    check    => $uptime_linux,
    warning  => $seuil_warning,
    critical => $seuil_critical,
);

$plugin_nagios->plugin_exit( $code_retour, 'Uptime - ' . time_format($uptime_linux) );

sub uptime {
    open my $fh, '<', '/proc/uptime'
      or $plugin_nagios->plugin_exit( CRITICAL, "/proc/uptime not exists, unable to get uptime\n" ), return;
    my ( $uptime, undef ) = split / /, <$fh>;
    close $fh;
    return $uptime;
}

sub time_format {
    my $totalsecondes = shift;

    if ( not defined $totalsecondes ) {
        $plugin_nagios->plugin_exit( CRITICAL, "uptime not found" );
    }
    return '0 seconde' if ( $totalsecondes == 0 );

    my $message = '';
    my ( $nbr_annees, $nbr_mois, $nbr_jours, $nbr_heures, $nbr_minutes, $nbr_secondes ) = ();

    # Annees
    my $duree_an = 60 * 60 * 24 * 30.41 * 12;
    $nbr_annees = int( $totalsecondes / $duree_an );
    if ( $nbr_annees > 0 ) {
        $totalsecondes = $totalsecondes - ( int( $totalsecondes / $duree_an ) * $duree_an );
        $message .= ( $nbr_annees == 1 ) ? "$nbr_annees year " : "$nbr_annees years ";
    }

    # Mois
    my $duree_mois = 60 * 60 * 24 * 30.41;
    $nbr_mois = int( $totalsecondes / $duree_mois );
    if ( $nbr_mois > 0 ) {
        $totalsecondes = $totalsecondes - ( int( $totalsecondes / $duree_mois ) * $duree_mois );
        $message .= ( $nbr_mois == 1 ) ? "$nbr_mois month " : "$nbr_mois months ";
    }

    # Jours
    my $duree_jours = 60 * 60 * 24;
    $nbr_jours = int( $totalsecondes / $duree_jours );
    if ( $nbr_jours > 0 ) {
        $totalsecondes = $totalsecondes - ( int( $totalsecondes / $duree_jours ) * $duree_jours );
        $message .= ( $nbr_jours == 1 ) ? "$nbr_jours day " : "$nbr_jours days ";
    }

    # Heures
    my $duree_heures = 60 * 60;
    $nbr_heures = int( $totalsecondes / $duree_heures );
    if ( $nbr_heures > 0 ) {
        $totalsecondes = $totalsecondes - ( int( $totalsecondes / $duree_heures ) * $duree_heures );
        $message .= ( $nbr_heures == 1 ) ? "$nbr_heures hour " : "$nbr_heures hours ";
    }

    # Minutes
    my $duree_minutes = 60;
    $nbr_minutes = int( $totalsecondes / $duree_minutes );
    if ( $nbr_minutes > 0 ) {
        $totalsecondes = $totalsecondes - ( int( $totalsecondes / $duree_minutes ) * $duree_minutes );
        $message .= ( $nbr_minutes == 1 ) ? "$nbr_minutes minute " : "$nbr_minutes minutes ";
    }

    # Secondes
    $totalsecondes = int $totalsecondes;
    if ( $totalsecondes > 0 ) {
        $message .= ( $totalsecondes == 1 ) ? "$totalsecondes seconde " : "$totalsecondes secondes ";
    }

    return $message;
}

chmod +x check_uptime.pl

cpan -i Monitoring::Plugin

root@SERVEURLINUX:~# /usr/local/nagios/libexec/check_uptime.pl -w 30 -c 60
Check uptime WARNING - Uptime - 1 month 11 days 5 hours 36 minutes 21 secondes

# vi /usr/local/nagios/etc/nrpe.cfg
…
…
command[check_uptime]=/usr/local/nagios/libexec/check_uptime.pl -w $ARG1$ -c $ARG2$

# /usr/local/nagios/libexec/check_nrpe -H 127.0.0.1 -c check_uptime -a 30 60
Check uptime WARNING - Uptime - 1 month 11 days 5 hours 45 minutes 59 secondes

root@supervision:~# /usr/local/nagios/libexec/check_nrpe -H SERVEURLINUX -c check_uptime -a 30 60
Check uptime WARNING - Uptime - 1 month 11 days 5 hours 47 minutes 34 secondes

# Vérification Uptime
define service{
    use                     generic-service
    host_name               SERVEURLINUX
    service_description     Vérification Uptime
    check_command           check_nrpe!check_uptime!30!60
}

root@supervision:~# /usr/local/nagios/libexec/check_nt -H SERVEURWINDOWS -v PROCSTATE -s MOTDEPASSE -p 12489
Pas de service/processus spécifié
root@supervision:~# /usr/local/nagios/libexec/check_nt -H SERVEURWINDOWS -v PROCSTATE -s MOTDEPASSE -p 12489 -d SHOWALL -l toto
 toto: not running
root@supervision:~# /usr/local/nagios/libexec/check_nt -H SERVEURWINDOWS -v PROCSTATE -s MOTDEPASSE -p 12489 -d SHOWALL -l explorer.exe
 Explorer.EXE: Running
root@supervision:~# /usr/local/nagios/libexec/check_nt -H SERVEURWINDOWS -v PROCSTATE -s MOTDEPASSE -p 12489 -l explorer.exe
 OK: All processes are running.
root@supervision:~# /usr/local/nagios/libexec/check_nt -H SERVEURWINDOWS -v PROCSTATE -s MOTDEPASSE -p 12489 -l toto
 toto: not running
root@supervision:~# /usr/local/nagios/libexec/check_nt -H SERVEURWINDOWS -v PROCSTATE -s MOTDEPASSE -p 12489 -l explorer.exe,mysql.exe
 mysql.exe: not running
root@supervision:~# /usr/local/nagios/libexec/check_nt -H SERVEURWINDOWS -v PROCSTATE -s MOTDEPASSE -p 12489 -d SHOWALL -l explorer.exe,mysql.exe
 Explorer.EXE: Running - mysql.exe: not running

root@supervision:~# /usr/local/nagios/libexec/check_nt -H SERVEURWINDOWS -v SERVICESTATE -s MOTDEPASSE -p 12489 -d SHOWALL -l "wuauserv"                                                wuauserv: Started
root@supervision:~# /usr/local/nagios/libexec/check_nt -H SERVEURWINDOWS -v SERVICESTATE -s MOTDEPASSE -p 12489 -d SHOWALL -l "OCS Inventory Service"
 OCS Inventory Service: Started
root@supervision:~# /usr/local/nagios/libexec/check_nt -H SERVEURWINDOWS -v SERVICESTATE -s MOTDEPASSE -p 12489 -d SHOWALL -l "toto"
 toto: Not found

define service{
    use            generic-service
    host_name        SERVEURWINDOWS
    service_description    Explorer
    check_command        check_nt!PROCSTATE!-d SHOWALL -l Explorer.exe
    }

define service{
    use            generic-service
    host_name        SERVEURWINDOWS
    service_description    MySQL 
    check_command        check_nt!SERVICESTATE!-d SHOWALL -l "MySQL"
}

#!/usr/bin/perl
#==============================================================
# Auteur : Djibril
# But    : Plugin nagios permettant de vérifier l'existence d'un
#          processus via le nom et/ou la commande système
# Date   : 31/10/2013
#==============================================================

use warnings;
use strict;
use Monitoring::Plugin;
use Proc::ProcessTable;
use vars qw/ $VERSION /;

# Version du plugin
$VERSION = '1.0';

my $LICENCE = 'This Plugin is free';
my $plugin_nagios = Monitoring::Plugin->new(
    shortname => 'Check process',
    usage     => 'Usage: %s [ -proc_name|-n=<Process name> ] [ -path|-p=<Path> ]',
    version   => $VERSION,
    license   => $LICENCE,
);

# Définition des options de ligne de commande
# 1- Récupération du nom du processus
$plugin_nagios->add_arg(
    spec     => 'proc_name|n=s',
    help     => 'Process name',
    label    => 'STRING',
    required => 1,
);

# 2- CmdLine du processus
$plugin_nagios->add_arg(
    spec     => 'path|p=s',
    help     => 'Command line of process',
    label    => 'STRING',
    required => 0,
);

# Parser les options
$plugin_nagios->getopts;

# Recherche du processus
my $process_table = new Proc::ProcessTable;

my $proc_name = $plugin_nagios->opts->proc_name;

PROC:
foreach my $proc ( @{ $process_table->table } ) {
    if ( $proc->fname eq $proc_name ) {
        my $message_OK = "Process $proc_name (" . $proc->pid . ') state (' . $proc->state . ')';

        # Path definie par nagios
        if ( my $path = $plugin_nagios->opts->path and $plugin_nagios->opts->path !~ m{^\s*$} ) {
            if ( $proc->cmndline ne $path ) {
                $plugin_nagios->plugin_exit( WARNING, "Process $proc_name exists but not path : $path" );
                last PROC;
            }
            $plugin_nagios->plugin_exit( OK, $message_OK );
        }
        $plugin_nagios->plugin_exit( OK, $message_OK );
    }
}

$plugin_nagios->plugin_exit( CRITICAL, "$proc_name not found" );

chmod +x check_process.pl

cpan -i Monitoring::Plugin Proc::ProcessTable

root@SERVEURLINUX:~# /usr/local/nagios/libexec/check_process.pl -n mysqld
Check process OK - Process mysqld (3159) state (sleep)

# vi /usr/local/nagios/etc/nrpe.cfg
…
…
command[check_process]=/usr/local/nagios/libexec/check_process.pl -n $ARG1$

root@supervision:~# /usr/local/nagios/libexec/check_nrpe -H SERVERULINUX -c check_process -a mysqld
Check process OK - Process mysqld (3159) state (sleep)

define service{
    use                     generic-service
    host_name               SERVERULINUX
    service_description     Check MySQL
    check_command           check_nrpe!check_process_ah!mysqld
    }

cpan -i  Monitoring::Plugin Net::NTP

#!/usr/bin/perl
#===============================================================================
# Auteur : djibril
# Date   : 19/11/2013
# But    : Check NTP
#===============================================================================
use strict;
use warnings;

use Monitoring::Plugin;
use Net::NTP qw(get_ntp_response);
use Data::Dumper;
use vars qw/ $VERSION /;

# Version du plugin
$VERSION = '1.0';

my $LICENCE = 'This Plugin is free';

my $plugin_nagios = Monitoring::Plugin->new(
    shortname => 'Check NTP',
    usage     => 'Usage : %s  -H <host> [-4|-6] [-w <warn>] [-c <crit>] [-v verbose]',
    version   => $VERSION,
    license   => $LICENCE,
);

$plugin_nagios->add_arg(
    spec     => 'warning|w=f',
    help     => 'warning offset',
    label    => 'SECONDE',
    required => 0,
);

$plugin_nagios->add_arg(
    spec     => 'critical|c=f',
    help     => 'critical offset',
    label    => 'SECONDE',
    required => 0,
);

$plugin_nagios->add_arg(
    spec     => 'port|p=i',
    help     => 'port number, defaut 123',
    label    => 'INTEGER',
    required => 0,
    default  => 123,
);

$plugin_nagios->add_arg(
    spec     => 'hostname|H=s',
    help     => 'Hostname of server',
    label    => 'STRING',
    required => 1,
);

# Activer le parsing des options de ligne de commande
$plugin_nagios->getopts;

my %ntp_response = get_ntp_response( $plugin_nagios->opts->hostname );
my $offset =
  ( ( $ntp_response{'Receive Timestamp'} - $ntp_response{'Originate Timestamp'} ) +
      ( $ntp_response{'Transmit Timestamp'} - time() ) ) / 2;

my $seuil_warning  = $plugin_nagios->opts->warning;
my $seuil_critical = $plugin_nagios->opts->critical;
my $code_retour    = $plugin_nagios->check_threshold(
    check    => abs($offset),
    warning  => $seuil_warning,
    critical => $seuil_critical,
);

$seuil_warning  = ( defined $seuil_warning )  ? $seuil_warning  : 0;
$seuil_critical = ( defined $seuil_critical ) ? $seuil_critical : 0;
if ( $plugin_nagios->opts->verbose ) {
    foreach ( keys %ntp_response ) {
        print "$_ : $ntp_response{$_}\n";
    }
}
$plugin_nagios->plugin_exit( $code_retour,
    sprintf( 'Offset %.6f secs|offset=%.6fs;%.6f;%.6f;', $offset, $offset, $seuil_warning, $seuil_critical ) );

C:\Program Files\NSCLIENT++\scripts>perl check_ntp.pl -H SERVEURNTP -w 1 -c 2
Check NTP OK - Offset 0.570322 secs|offset=0.570322s;0.000000;0.000000;

NRPEListener.dll
CheckExternalScripts.dll

allow_arguments=1

check_ntp=C:\Perl\bin\perl.exe scripts\check_ntp.pl -H $ARG1$ -w $ARG2$ -c $ARG3$

root@supervision:~# /usr/local/nagios/libexec/check_nrpe -H SERVEURWINDOWS -c check_ntp -a SERVEURNTP 1 2
Check NTP WARNING - Offset 1.693763 secs|offset=1.693763s;1.000000;2.000000;

# Verification NTP
define service{
    use                     generic-service
    host_name               SERVEURWINDOWS
    service_description     Date du serveur
    check_command           check_nrpe!check_ntp!SERVEURNTP!1!2
}

# Verification NTP
define service{
    use                     generic-service
    host_name               SERVEURLINUX
    service_description     Date du serveur
    check_command           check_nrpe!check_ntp_time!SERVEURNTP!1!2
    }

define service {
    use                   generic-service
    host_name             switch ou IP
    service_description   PING
    check_command         check_ping!200.0,20%!600.0,60%
    normal_check_interval 5
    retry_check_interval  1
}

root@supervision:~# snmpwalk -v1 -c public switch2 | more
iso.3.6.1.2.1.1.1.0 = STRING: "ProCurve J9087A Switch 2610-24-PWR, revision R.11.60, ROM R.10.06 (/sw/code/build/nemo(R_ndx))"
iso.3.6.1.2.1.1.2.0 = OID: iso.3.6.1.4.1.11.2.3.7.11.78
iso.3.6.1.2.1.1.3.0 = Timeticks: (3560265850) 412 days, 1:37:38.50
iso.3.6.1.2.1.1.4.0 = ""
iso.3.6.1.2.1.1.5.0 = STRING: "switch2"
iso.3.6.1.2.1.1.6.0 = STRING: "EtageLogement"
iso.3.6.1.2.1.1.7.0 = INTEGER: 78
iso.3.6.1.2.1.2.1.0 = INTEGER: 32
iso.3.6.1.2.1.2.2.1.1.1 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.1.2 = INTEGER: 2
iso.3.6.1.2.1.2.2.1.1.3 = INTEGER: 3
iso.3.6.1.2.1.2.2.1.1.4 = INTEGER: 4
iso.3.6.1.2.1.2.2.1.1.5 = INTEGER: 5
iso.3.6.1.2.1.2.2.1.1.6 = INTEGER: 6
iso.3.6.1.2.1.2.2.1.1.7 = INTEGER: 7
iso.3.6.1.2.1.2.2.1.1.8 = INTEGER: 8
iso.3.6.1.2.1.2.2.1.1.9 = INTEGER: 9
iso.3.6.1.2.1.2.2.1.1.10 = INTEGER: 10
iso.3.6.1.2.1.2.2.1.1.11 = INTEGER: 11

.1.3.6.1.2.1.2.2.1.8.x

root@supervision:~# snmpwalk -v1 -c public switch2 .1.3.6.1.2.1.2.2.1.8 | more
iso.3.6.1.2.1.2.2.1.8.1 = INTEGER: 2
iso.3.6.1.2.1.2.2.1.8.2 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.8.3 = INTEGER: 2
iso.3.6.1.2.1.2.2.1.8.4 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.8.5 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.8.6 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.8.7 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.8.8 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.8.9 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.8.10 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.8.11 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.8.12 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.8.13 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.8.14 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.8.15 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.8.16 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.8.17 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.8.18 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.8.19 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.8.20 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.8.21 = INTEGER: 2
iso.3.6.1.2.1.2.2.1.8.22 = INTEGER: 2
iso.3.6.1.2.1.2.2.1.8.23 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.8.24 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.8.25 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.8.26 = INTEGER: 2
iso.3.6.1.2.1.2.2.1.8.27 = INTEGER: 2
iso.3.6.1.2.1.2.2.1.8.28 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.8.101 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.8.106 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.8.107 = INTEGER: 1
iso.3.6.1.2.1.2.2.1.8.4196 = INTEGER: 1

root@supervision:~# /usr/local/nagios/libexec/check_snmp -H switch2 -o .1.3.6.1.2.1.2.2.1.8.1 -r 1
SNMP CRITICAL - *2* | iso.3.6.1.2.1.2.2.1.8.1=2

# Monitor Port 1 status via SNMP
define service{
    use            generic-service    ; Inherit values from a template
    host_name        switch2
    service_description    Port 01 Link Status
    check_command        check_snmp!-C public -o .1.3.6.1.2.1.2.2.1.8.1 -r 1 
    }