Perl et les bases de données (DBI)

MySQL, Oracle…

djibril

Ce tutoriel vous permettra d'apprendre les bases d'utilisation du module DBI afin de se connecter à une base de données et de lire ou insérer des données.
La notion des placeholders pour protéger et optimiser les requêtes sera abordée. Commentez

- Titre : Perl et les bases de données (DBI)

- Auteur : djibril

- Parution : 26 janvier 2009

- Mise à jour : 19 mai 2013

- Public visé :

- Licence : Les sources présentées sur cette page sont libres de droits et vous pouvez les utiliser à votre convenance. Par contre, la page de présentation constitue une œuvre intellectuelle protégée par les droits d'auteur. Copyright ® 2013 djibril. Aucune reproduction, même partielle, ne peut être faite de ce site et de l'ensemble de son contenu : textes, documents, images, etc. sans l'autorisation expresse de l'auteur. Sinon vous encourez selon la loi jusqu'à trois ans de prison et jusqu'à 300 000 € de dommages et intérêts.

Sommaire

- I. Introduction

- I-A. Les bases de données

- I-B. Interaction avec les bases de données

- II. Perl et les bases de données

- II-A. Prérequis pour travailler

- II-B. Modules Perl nécessaires

- II-C. Débuter par l'exemple

- II-C-1. Enoncé de l'exercice

- II-C-2. Création de la base de données, des tables SQL et insertion des données

- II-C-2-a. Exemple sous Oracle

- II-C-3. Interrogation de la base de données

- II-C-3-a. Lister tous les départements d'une région

- II-C-3-b. Afficher le nom du département, de la région et le nombre de communes en fonction d'un numéro de département

- II-C-3-c. Trouver le nom du département et de la région d'une commune donnée

- II-C-4. Exemple sous Oracle

- II-C-5. Téléchargement des programmes

- III. Liens

- IV. Conclusion

- V. Remerciements

I - Introduction

Le but de ce tutoriel est d'apprendre à interagir avec les bases de données en Perl.
Nous commencerons par définir la notion de base de données. Il vous sera ensuite expliqué et listé ce dont vous avez besoin pour travailler.

I-A - Les bases de données

Une base de données (communément appelée « BD »" ou « database » en anglais) est une entité dans laquelle on stocke des informations de façon structurée. Il est possible de localiser facilement ces données et de les mettre rapidement à jour.
Un autre avantage de la BD est qu'elle peut être interrogée par plusieurs personnes, dans un réseau sécurisé, par l'intermédiaire d'un système de gestion de base de données (communément abrégé « SGBD »).

Le terme entité peut vous paraître abstrait. Pour mieux comprendre, retenez qu'une base de données n'est en fait qu'un ensemble de tables de données, un peu à la manière dont vous pourriez inscrire des données dans une feuille de tableur (Excel ou autre).

Le but de ce tutoriel n'est pas de vous apprendre les notions de BD et SGBD, reportez-vous aux cours du site de developpez.com pour avoir de plus amples informations sur ce sujet.

Voici quelques liens :

- des cours SQL ;

- des cours SGBD ;

- et vous en trouverez facilement d'autres sur developpez.com.

I-B - Interaction avec les bases de données

Il existe différentes façons d'interagir avec une base de données :

- en ligne de commande via une console Dos, Unix, Linux… ;

- à partir d'une interface web (avec un logiciel comme phpMyAdmin) ;

- via un langage de programmation comme Perl.

Notez que Perl n'est pas le seul langage qui permet d'interroger une base de données. La plupart des langages de programmation le permettent (ex : PHP, Java, C#…).

II - Perl et les bases de données

Cette section du tutoriel permet de rentrer dans le vif du sujet ! Il faut dans un premier temps installer les outils nécessaires pour commencer à travailler sur les bases de données avec Perl.

II-A - Prérequis pour travailler

Pour pouvoir créer ou interroger une base de données, vous devez dans un premier temps installer un système de gestion de base de données (MySQL, PostgreSQL, ou autres). Il en existe beaucoup. Si vous avez installé EasyPHP, vous disposez d'un SGBD.

II-B - Modules Perl nécessaires

Perl a besoin du module DBI pour interagir avec les bases de données et d'un module driver pour les SGBD. Dans cet article, nous utiliserons MySQL comme SGBD. Nous aurons besoin du module driver adéquat : DBD::mysql.

Sachez qu'il existe des drivers pour toutes les SGBD que vous souhaiterez utiliser. Ils sont disponibles sur le site du CPAN et sont généralement sous la forme DBD::*.

Exemple de drivers

- DBD::Pg PostgreSQL database driver for the DBI module ;

- DBD::Oracle Oracle database driver for the DBI module ;

- DBD::Sybase Sybase database driver for the DBI module ;

- DBD::Ingres DBI driver for Ingres database systems ;

- site officiel de Perl DBI ;

- …

Si vous rencontrez des difficultés dans l'installation des modules, lisez le tutoriel sur l'installation des modules Perl écrit par nos soins ! Sinon, le forum Perl est toujours à votre disposition !

II-C - Débuter par l'exemple

Nous sommes maintenant prêts à coder ! La meilleure façon d'apprendre est de faire un exemple. Voici donc l'énoncé d'un exercice qui nous permettra de comprendre les commandes de base.

II-C-1 - Enoncé de l'exercice

Afin de jouer avec le module DBI, nous allons créer un programme dont le but sera d'effectuer les tâches suivantes :

- lister tous les départements d'une région ;

- afficher le nom du département, de la région et le nombre de communes en fonction d'un numéro de département ;

- donner le nom du département et de la région d'une commune.

Pour résoudre cet exercice, il faut que l'on puisse accéder à ces informations. Pour cela, nous téléchargeons trois fichiers contenant toutes les communes, départements et régions de France connus au 1er janvier 2013 sur le site de l'INSEE. Grâce à ces fichiers, on crée une base de données et trois tables SQL.

Voici un affichage de quelques lignes de ces fichiers :

Exemple du fichier des régions de France

REGION

CHEFLIEU

TNCC

NCC

NCCENR

1

971053

3

GUADELOUPE

Guadeloupe

11

75056

1

ILE-DE-FRANCE

Île-de-France

Exemple du fichier des communes de France

CDC

CHEFLIEU

REG

DEP

COM

AR

CT

TNCC

ARTMAJ

NCC

ARTMIN

NCCENR

1

4

11

75

56

1

99

0

PARIS

Paris

0

0

82

1

42

2

27

0

BEY

Bey

0

0

24

41

023

1

13

0

BOURRE

Bourré

0

0

82

26

142

1

06

0

GLANDAGE

Glandage

0

0

74

87

003

1

28

1

ARNAC-LA-POSTE

Arnac-la-Poste

Exemple du fichier des départements de France

REGION

DEP

CHEFLIEU

TNCC

NCC

NCCENR

82

1

1053

5

AIN

Ain

22

2

2408

5

AISNE

Aisne

II-C-2 - Création de la base de données, des tables SQL et insertion des données

Créons une base de données que nous nommerons France2013 via une console (ou une interface Web).

Commande SQL

1. /*    Création de la base de données France2013 */

2. CREATE DATABASE `France2013`;

1. C:\>mysql -u root -p

2. Enter password: *****

3. Welcome to the MySQL monitor.  Commands end with ; or \g.

4. Your MySQL connection id is 25

5. Server version: 5.1.31-community MySQL Community Server (GPL)

7. Type 'help;' or '\h' for help. Type '\c' to clear the buffer.

9. mysql> CREATE DATABASE `France2013`;

10. Query OK, 1 row affected (0.04 sec)

La suite sera totalement intégrée dans un script Perl.
Créons un script CreationTableSQLFrance.pl qui se charge de créer les tables SQL et de les remplir avec les données du fichier.

Voici notre programme :

CreationTableSQLFrance.pl

1. #!/usr/bin/perl

2. #========================================================================================

3. # Auteur : djibril

4. # But     : Création des tables SQL et insertion de données

5. #

6. # http://djibril.developpez.com/tutoriels/perl/perl-dbi/

7. #========================================================================================

8. use warnings;

9. use strict;

10. use Encode;

11. use utf8;

12. use DBI;            # Charger le module DBI

13. use vars qw/ $VERSION /;    # Version du script

14. $VERSION = '1.0';

16. ActiverAccents();

18. # Paramètres de connection à la base de données

19. my $bd        = 'France2013';

20. my $serveur    = 'localhost'; # Il est possible de mettre une adresse IP

21. my $identifiant = 'root';      # identifiant

22. my $motdepasse    = '';

23. my $port    = '';        #Si vous ne savez pas, ne rien mettre

25. # Connection à la base de données mysql

26. print "Connexion à la base de données $bd\n";

27. my $dbh = DBI->connect( "DBI:mysql:database=$bd;host=$serveur;port=$port",

28. $identifiant, $motdepasse, {

29. RaiseError => 1,

30. }

31. ) or die "Connection impossible à la base de données $bd !\n $! \n $@\n$DBI::errstr";

33. # Création des tables

34. print "Création de la table Regions\n";

35. my $sql_creation_table_regions = <<"SQL";

36. CREATE TABLE Regions (

37. id_region INT         NOT NULL ,

38. cheflieu  VARCHAR( 6 )    NOT NULL ,

39. tncc        INT         NOT NULL ,

40. ncc        VARCHAR( 100 )  NOT NULL ,

41. nccenr    VARCHAR( 100 )  NOT NULL ,

42. PRIMARY KEY ( id_region )

43. )  COMMENT = 'LES REGIONS 2013 EN FRANCE';

44. SQL

46. $dbh->do('DROP TABLE IF EXISTS Regions;') or die "Impossible de supprimer la table Regions\n\n";

47. $dbh->do($sql_creation_table_regions) or die "Impossible de créer la table Regions\n\n";

49. print "Création de la table Communes\n";

50. my $sql_creation_table_communes = <<"SQL";

51. CREATE TABLE Communes (

52. id_communes      INT          NOT NULL AUTO_INCREMENT PRIMARY KEY COMMENT 'Elle sera générée automatiquement.',

53. cdc          INT          NOT NULL ,

54. cheflieu      VARCHAR( 6 )      NOT NULL ,

55. id_region      INT          NOT NULL ,

56. id_departement  VARCHAR( 10 )   NOT NULL ,

57. com          INT          NOT NULL ,

58. ar          INT          NOT NULL ,

59. ct          INT          NOT NULL ,

60. tncc          INT          NOT NULL ,

61. artmaj      VARCHAR( 20 )   ,

62. ncc          VARCHAR( 100 )  NOT NULL ,

63. artmin      VARCHAR( 20 )   ,

64. nccenr      VARCHAR( 100 )  NOT NULL

65. ) COMMENT = 'LES COMMUNES 2013 EN FRANCE';

66. SQL

68. $dbh->do('DROP TABLE IF EXISTS Communes;') or die "Impossible de supprimer la table Communes\n\n";

69. $dbh->do($sql_creation_table_communes) or die "Impossible de créer la table Communes\n\n";

71. print "Création de la table Departements\n";

72. my $sql_creation_table_departements = <<"SQL";

73. CREATE TABLE Departements  (

74. id_departement  VARCHAR( 10 )   NOT NULL COMMENT 'les valeurs sont uniques',

75. id_region      INT          NOT NULL ,

76. cheflieu      VARCHAR( 6 )      NOT NULL ,

77. tncc          INT          NOT NULL ,

78. ncc          VARCHAR( 100 )  NOT NULL ,

79. nccenr      VARCHAR( 100 )  NOT NULL ,

80. PRIMARY KEY ( id_departement )

81. ) COMMENT = 'LES DEPARTEMENTS 2013 EN FRANCE';

82. SQL

84. $dbh->do('DROP TABLE IF EXISTS Departements;') or die "Impossible de supprimer la table Departements\n\n";

85. $dbh->do($sql_creation_table_departements) or die "Impossible de créer la table Departements\n\n";

87. # Lecture des fichiers et insertion des données

88. my $fichier_regions     = 'reg2013.txt';

89. my $fichier_communes     = 'comsimp2013.txt';

90. my $fichier_departements = 'depts2013.txt';

92. # Fichier Region

93. print "Insertion des données dans la table regions\n";

94. open my $fh_regions, '<:encoding(UTF-8)', $fichier_regions or die "Impossible de lire le fichier $fichier_regions\n";

95. my $entete_fichier_region = <$fh_regions>;

97. # Insertion des données

98. my $requete_sql_region = <<"SQL";

99. INSERT INTO regions ( id_region, cheflieu, tncc, ncc, nccenr )

100. VALUES ( ?, ?, ?, ?, ? );

101. SQL

103. my $sth_regions = $dbh->prepare($requete_sql_region);

105. while ( my $ligne = <$fh_regions> ) {

106. chomp $ligne;

107. my ( $REGION, $CHEFLIEU, $TNCC, $NCC, $NCCENR ) = split /\t/, $ligne;

108. $sth_regions->execute( $REGION, $CHEFLIEU, $TNCC, encode('latin1',$NCC), encode('latin1',$NCCENR) )

109. or die "Echec Requ&#234;te $requete_sql_region : $DBI::errstr";

110. }

111. close $fh_regions;

113. # Fichier Communes

114. print "Insertion des données dans la table Communes\n";

115. open my $fh_communes, '<:encoding(UTF-8)', $fichier_communes or die "Impossible de lire le fichier $fichier_communes\n";

116. my $entete_fichier_communes = <$fh_communes>;

118. # Insertion des données

119. my $requete_sql_communes = <<"SQL";

120. INSERT INTO communes (

121. id_communes, cdc,         cheflieu,

122. id_region,     id_departement, com,

123. ar,      ct,         tncc,

124. artmaj,     ncc,         artmin,

125. nccenr )

126. VALUES ( ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ? );

127. SQL

129. my $sth_communes = $dbh->prepare($requete_sql_communes);

130. while ( my $ligne = <$fh_communes> ) {

131. chomp $ligne;

132. my ( $CDC, $CHEFLIEU, $REG, $DEP, $COM, $AR, $CT, $TNCC, $ARTMAJ, $NCC, $ARTMIN, $NCCENR ) = split /\t/,

133. $ligne;

135. $sth_communes->execute( undef, $CDC, $CHEFLIEU, $REG, $DEP, $COM, $AR, $CT, $TNCC, $ARTMAJ, $NCC, encode('latin1',$ARTMIN),

136. encode('latin1',$NCCENR) )

137. or die "Echec Requ&#234;te $requete_sql_communes : $DBI::errstr";

138. }

139. close $fh_communes;

141. # Fichier Departements

142. print "Insertion des données dans la table Departements\n";

143. open my $fh_departements, '<:encoding(UTF-8)', $fichier_departements

144. or die "Impossible de lire le fichier $fichier_departements\n";

145. my $entete_fichier_departements = <$fh_departements>;

147. # Insertion des données

148. my $requete_sql_departement = <<"SQL";

149. INSERT INTO Departements (

150. id_departement, id_region, cheflieu,

151. tncc,        ncc,       nccenr )

152. VALUES ( ?, ?, ?, ?, ?, ? );

153. SQL

155. my $sth_departements = $dbh->prepare($requete_sql_departement);

156. while ( my $ligne = <$fh_departements> ) {

157. chomp $ligne;

158. my ( $REGION, $DEP, $CHEFLIEU, $TNCC, $NCC, $NCCENR ) = split /\t/, $ligne;

159. $sth_departements->execute( $DEP, $REGION, $CHEFLIEU, $TNCC, $NCC, encode('latin1',$NCCENR) )

160. or die "Echec Requ&#234;te $requete_sql_departement : $DBI::errstr";

161. }

162. close $fh_departements;

164. # Déconnection de la base de données

165. $dbh->disconnect();

167. #==============================================================

168. # Pour avoir les accents sur la console DOS ou non

169. # https://perl.developpez.com/faq/perl/?page=Terminal#Accents

170. #==============================================================

171. sub ActiverAccents {

172. my $encodage;

173. # Windows

174. if ( lc($^O ) eq 'mswin32') {

175. eval {

176. my ($codepage) = ( `chcp` =~ m/:\s+(\d+)/ );

177. $encodage = "cp$codepage";

178. foreach my $h ( \*STDOUT, \*STDERR, \*STDIN, ) {

179. binmode $h, ":encoding($encodage)";

180. }

181. };

182. }

183. else {

184. $encodage = `locale charmap`;

185. eval {

186. foreach my $h ( \*STDOUT, \*STDERR, \*STDIN, ) {

187. binmode $h, ":encoding($encodage)";

188. }

189. };

190. }

191. return $encodage;

192. }

- Explication :

Nous utilisons le module Encode pour l'encodage des caractères avant insertion des données dans la bases. Notre programme est encodé en utf-8 d'où le chargement du module « utf8 ».
Puis nous utilisons le module DBI.

Le code

1. ActiverAccents();

permet d'avoir un affichage correct des accents sous sa console. Pour en savoir plus, la FAQ Perl à ce sujet.

Ensuite, on se connecte à la base de données via la méthode connect. Si nous avions utilisé un SGBD tel PostgreSQL, nous aurions écrit ceci :

Connexion à la base de données PostgreSQL

1. # Connection à la base de données  PostgreSQL

2. print "Connexion à la base de données $bd\n";

3. my $dbh = DBI->connect( "DBI:Pg:database=$bd;host=$serveur;port=$port",

4. $identifiant, $motdepasse, {

5. RaiseError => 1,

6. }

7. ) or die "Connection impossible à la base de données $bd !\n $! \n $@\n$DBI::errstr";

C'est donc à ce niveau que le module DBI distingue le driver à utiliser et effectue la connexion à notre base. Créons maintenant les tables SQL.

Les tables SQL sont créées (et au préalable supprimées si elles existaient). Nous avons utilisé la méthode do qui peut être utilisée pour toutes les commandes SQL non répétées (c'est-à-dire requêtes exécutées une seule fois) qui ne sont pas de type SELECT.

Ligne 92 - à la fin : insertion des données dans les tables SQL.

Nous déclarons les variables contenant les noms des fichiers à analyser pour remplir nos tables SQL. Il faut garder à l'esprit que les fichiers sont encodés en UTF-8 d'où la lecture sous cette encodage des fichiers.

Prenons pour exemple le fichier Region.
En ligne 93, nous lisons l'entête du fichier (ligne 1 du fichier) et en lignes 98-101, nous construisons notre requête d'insertion. Vous remarquez à ce niveau que dans notre requête, nous avons des points d'interrogation. En fait, nous allons utiliser la notion de placeholders.

- Qu'est-ce que les placeholders ?

Il existe ce qu'on appelle des placeholders dans le module DBI qui permettent d'exécuter les requêtes SQL lancées par Perl plus rapidement et de les protéger. Ils protègent efficacement contre l'injection SQL (fléau des sites web dynamiques), comme DBI est souvent utilisé dans un contexte web.

Ils sont supportés par la plupart des drivers. Je suis incapable de vous dire les drivers qui ne les supportent pas car ce n'est pas précisé dans la documentation.

Si un sympathique lecteur en a la liste, qu'il me fasse signe, je suis preneur !! Ayant utilisé DBD::Mysql et DBD::Pg, je n'ai jamais eu de souci.

- Revenons à notre exemple

Nous allons lire notre fichier ligne à ligne et exécuter plusieurs fois le même type de requête. Seules les données changent, mais l'insertion se fera toujours dans les mêmes champs. Nous avons donc préparé notre requête (grâce à la méthode prepare) en dehors de la boucle while (ligne 103). Cela évite à DBI de devoir créer la requête à chaque ligne du fichier (perte de performance).

Une fois la requête conçue, nous lisons notre fichier ligne à ligne, récupérons les données (tabulées) et exécutons la requête grâce à la méthode execute (lignes 108,109). C'est le même principe pour les trois fichiers.

N.B. En ligne 135, nous avons mis le terme undef. En fait, pour le champ id_communes, nous avons mis un attribut AUTO_INCREMENT qui permet de générer un identifiant unique pour toutes les nouvelles lignes.

1. id_communes  INT   NOT NULL AUTO_INCREMENT PRIMARY KEY COMMENT 'Elle sera générée automatiquement.',

Notre requête SQL ressemble à :

1. INSERT INTO communes (

2. id_communes, cdc,         cheflieu,

3. id_region,     id_departement, com,

4. ar,      ct,         tncc,

5. artmaj,     ncc,         artmin,

6. nccenr )

7. VALUES ( ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ? );

Nous avons exécuté cette requête de la sorte :

1. $sth_communes->execute( undef, $CDC, $CHEFLIEU, $REG, $DEP, $COM, $AR, $CT, $TNCC, $ARTMAJ, $NCC,

2. encode('latin1',$ARTMIN), encode('latin1',$NCCENR) )

3. or die "Echec Requ&#234;te $requete_sql_communes : $DBI::errstr";

Mettre undef permet à Perl de dire à SQL qu'il s'agit de la valeur NULL. Comme ce champ contient l'attribut AUTO_INCREMENT, SQL incrémentera tout seul la valeur du champ.

Notre base de données est encodée en latin, donc nous encodant certains champs où il est susceptible d'avoir des accents afin d'avoir des caractères correctement affichés dans la base.

1. encode('latin1',$ARTMIN)

Petit Résumé :

Les méthodes prepare et execute sont généralement utilisées pour toutes les requêtes différentes du type SELECT (exemple : INSERT, UPDATE…).
Vous me direz, mais do aussi ! Alors laquelle choisir ?

Si vous avez une requête à exécuter une seule fois, comme une création de table (comme dans notre script), la mise à jour d'une seule ligne dans votre table SQL, la méthode do est recommandée. Par contre, si vous avez plusieurs requêtes à lancer, comme c'est le cas pour l'insertion des données, il est conseillé d'utiliser les méthodes prepare et execute car il sera plus simple de les optimiser via l'utilisation des placeholders.

Voilà, notre premier script nous permet de créer nos tables et d'y insérer les données.

II-C-2-a - Exemple sous Oracle

dmganges a repris l'exemple précédent pour proposer un exemple sous Oracle comme nous allons le voir. Il y a quelques légères modifications :

- requêtes de création sous forme de fichier.sql pour centraliser les créations, çà c'est une préférence perso ;

- modification table COMMUNES car Oracle ne gère pas les colonnes AUTO_INCREMENT, remplacement par une SEQUENCE et un TRIGGER

OracleCreationTableFrance.pl

1. #!/usr/bin/perl

2. #========================================================================================

3. # Auteur : djibril

4. # But     : Création des tables SQL et insertion de données

5. #

6. # http://djibril.developpez.com/tutoriels/perl/perl-dbi/

7. #

8. # Quelques modifs mineures par dmganges pour Oracle :

9. # - Modification table COMMUNES car Oracle ne gère pas les colonnes AUTO_INCREMENT

10. #         Remplacement par une SEQUENCE et un TRIGGER

11. #========================================================================================

12. use warnings;

13. use strict;

14. use utf8;

15. use DBI;                      # Charge le module DBI

17. use vars qw/ $VERSION /;              # Version du script

18. $VERSION = '1.0';

20. ActiverAccents();

22. # Paramètres de connexion à la base de données

23. my $host = "localhost";

24. my $port = "1521";

25. my $bdd  = "XE";

26. my $user = "michel";

27. my $pass = "michel";

29. my $dbh = DBI->connect("dbi:Oracle:host=$host;port=$port;sid=$bdd", $user, $pass, {

30. PrintError => 0,

31. AutoCommit => 0

32. }) or die "\nERR=Connexion impossible à la base de données $bdd\n $! \n $@\n$DBI::errstr";

34. my ($Sysdate) = $dbh->selectrow_array("SELECT sysdate FROM dual")

35. or die "\nERR=Sysdate\n $! \n $@\n$DBI::errstr";

36. print "Base OK Date = $Sysdate\n\n";

38. # Création des tables

39. foreach my $Script ( 'CreTabRegions.sql', 'CreTabCommunes.sql', 'CreTabDepartements.sql') {

40. print "Exécution de $Script\n";

41. open( SQL, $Script) or die "\nERR=open $Script\n $!";

42. my @Sqls = split(/\n\//,join('',<SQL>));

43. for my $Sql( @Sqls ){

44. # print "SEL=$Sql=\n";

45. if ( $Sql ) {

46. $dbh->do($Sql); # or die "\nERR=dbh->do\n $! \n $@\n$DBI::errstr";

47. }

48. }

49. close SQL;

50. }

52. # NB Suppression contrôle $DBI::errstr car dans CreTabCommunes.sql

53. # La création du trigger génère un WARNIG qui déclenche le or die

54. # Alors que le trigger est créé correctement !

56. # Lecture des fichiers et insertion des données

57. my $fichier_regions     = 'reg2013.txt';

58. my $fichier_communes     = 'comsimp2013.txt';

59. my $fichier_departements = 'depts2013.txt';

61. # Fichier Region

62. print "Insertion des données dans la table regions\n";

63. open my $fh_regions, '<:encoding(UTF-8)', $fichier_regions or die "\nERR=open $fichier_regions\n $!";

64. my $entete_fichier_region = <$fh_regions>;

66. # Insertion des données

67. my $requete_sql_region = <<"SQL";

68. INSERT INTO regions ( id_region, cheflieu, tncc, ncc, nccenr )

69. VALUES ( ?, ?, ?, ?, ? )

70. SQL

72. my $sth_regions = $dbh->prepare($requete_sql_region) or die "\nERR=dbh->prepare\n $! \n $@\n$DBI::errstr";

74. while ( my $ligne = <$fh_regions> ) {

75. chomp $ligne;

76. my ( $REGION, $CHEFLIEU, $TNCC, $NCC, $NCCENR ) = split /\t/, $ligne;

77. $sth_regions->execute( $REGION, $CHEFLIEU, $TNCC, $NCC, $NCCENR )

78. or die "\nERR=sth_regions->execute\n $! \n $@\n$DBI::errstr";

79. }

80. close $fh_regions;

82. # Fichier Communes

83. print "Insertion des données dans la table Communes\n";

84. open my $fh_communes, '<:encoding(UTF-8)', $fichier_communes or die "\nERR=open $fichier_communes\n $!";

85. my $entete_fichier_communes = <$fh_communes>;

87. # Insertion des données

88. my $requete_sql_communes = <<"SQL";

89. INSERT INTO communes (

90. id_communes, cdc,         cheflieu,

91. id_region,     id_departement, com,

92. ar,      ct,         tncc,

93. artmaj,     ncc,         artmin,

94. nccenr )

95. VALUES ( ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ?, ? )

96. SQL

98. my $sth_communes = $dbh->prepare($requete_sql_communes)

99. or die "\nERR=dbh->prepare\n $! \n $@\n$DBI::errstr";

100. while ( my $ligne = <$fh_communes> ) {

101. chomp $ligne;

102. my ( $CDC, $CHEFLIEU, $REG, $DEP, $COM, $AR, $CT, $TNCC, $ARTMAJ, $NCC, $ARTMIN, $NCCENR ) = split /\t/, $ligne;

103. $sth_communes->execute( undef, $CDC, $CHEFLIEU, $REG, $DEP, $COM, $AR, $CT, $TNCC, $ARTMAJ, $NCC, $ARTMIN, $NCCENR )

104. or die "\nERR=sth_communes->execute\n $! \n $@\n$DBI::errstr";

105. }

106. close $fh_communes;

108. # Fichier Departements

109. print "Insertion des données dans la table Departements\n";

110. open my $fh_departements, '<:encoding(UTF-8)', $fichier_departements or die "\nERR=open $fichier_departements\n $!";

111. my $entete_fichier_departements = <$fh_departements>;

113. # Insertion des données

114. my $requete_sql_departement = <<"SQL";

115. INSERT INTO Departements (

116. id_departement, id_region, cheflieu,

117. tncc,        ncc,       nccenr )

118. VALUES ( ?, ?, ?, ?, ?, ? )

119. SQL

121. my $sth_departements = $dbh->prepare($requete_sql_departement)

122. or die "\nERR=dbh->prepare\n $! \n $@\n$DBI::errstr";

123. while ( my $ligne = <$fh_departements> ) {

124. chomp $ligne;

125. my ( $REGION, $DEP, $CHEFLIEU, $TNCC, $NCC, $NCCENR ) = split /\t/, $ligne;

126. $sth_departements->execute( $DEP, $REGION, $CHEFLIEU, $TNCC, $NCC, $NCCENR )

127. or die "\nERR=sth_departements->execute\n $! \n $@\n$DBI::errstr";

128. }

129. close $fh_departements;

130. print "Fin insertion\n";

131. $dbh->disconnect() or die "\nERR=disconnect\n $! \n $@\n$DBI::errstr";

133. #==============================================================

134. # Pour avoir les accents sur la console DOS ou non

135. # https://perl.developpez.com/faq/perl/?page=Terminal#Accents

136. #==============================================================

137. sub ActiverAccents {

138. my $encodage;

139. # Windows

140. if ( lc($^O ) eq 'mswin32') {

141. eval {

142. my ($codepage) = ( `chcp` =~ m/:\s+(\d+)/ );

143. $encodage = "cp$codepage";

144. foreach my $h ( \*STDOUT, \*STDERR, \*STDIN, ) {

145. binmode $h, ":encoding($encodage)";

146. }

147. };

148. }

149. else {

150. $encodage = `locale charmap`;

151. eval {

152. foreach my $h ( \*STDOUT, \*STDERR, \*STDIN, ) {

153. binmode $h, ":encoding($encodage)";

154. }

155. };

156. }

157. return $encodage;

158. }

160. #The following conventions are used in this document:

161. #

162. #  $dbh    Database handle object

163. #  $sth    Statement handle object

164. #  $drh    Driver handle object (rarely seen or used in applications)

165. #  $h       Any of the handle types above ($dbh, $sth, or $drh)

166. #  $rc       General Return Code    (boolean: true=ok, false=error)

167. #  $rv       General Return Value (typically an integer)

168. #  @ary    List of values returned from the database, typically a row of data

169. #  $rows   Number of rows processed (if available, else -1)

170. #  $fh       A filehandle

171. #  undef   NULL values are represented by undefined values in Perl

172. #  \%attr  Reference to a hash of attribute values passed to methods

Voici le code des fichiers SQL qui seront de toutes façon disponibles en téléchargement.

Region

1. DROP TABLE Regions

2. /

4. CREATE TABLE Regions (

5. id_region INT         NOT NULL ,

6. cheflieu  VARCHAR( 6 )   NOT NULL ,

7. tncc      INT         NOT NULL ,

8. ncc       VARCHAR( 50 )  NOT NULL ,

9. nccenr    VARCHAR( 50 )  NOT NULL ,

10. PRIMARY KEY ( id_region )

11. ) tablespace USERS

12. /

14. COMMENT ON TABLE Regions is 'LES REGION DE FRANCE EN 2013'

15. /

Communes

1. DROP TABLE Communes

2. /

4. CREATE TABLE Communes (

5. id_communes     INT         NOT NULL ,

6. cdc         INT         NOT NULL ,

7. cheflieu        VARCHAR( 6 )    NOT NULL ,

8. id_region        INT         NOT NULL ,

9. id_departement  VARCHAR( 10 )   NOT NULL ,

10. com         INT         NOT NULL ,

11. ar            INT         NOT NULL ,

12. ct            INT,

13. tncc        INT         NOT NULL ,

14. artmaj        VARCHAR( 10 ),

15. ncc         VARCHAR( 50 )   NOT NULL ,

16. artmin        VARCHAR( 10 ),

17. nccenr        VARCHAR( 50 )   NOT NULL ,

18. PRIMARY KEY ( id_communes )

19. ) tablespace USERS

20. /

22. COMMENT ON TABLE Communes is 'LES COMMUNES DE FRANCE EN 2013'

23. /

25. DROP SEQUENCE id_communes_seq

26. /

28. CREATE SEQUENCE id_communes_seq start with 1 increment by 1

29. /

31. create or replace trigger communes_insert

32. before insert on communes

33. for each row

34. begin

35. select id_communes_seq.nextval into :new.id_communes from dual;

36. end communes_insert;

37. /

Département

1. DROP TABLE Departements

2. /

4. CREATE TABLE Departements  (

5. id_departement  VARCHAR( 3 )    NOT NULL ,

6. id_region        INT         NOT NULL ,

7. cheflieu        VARCHAR( 6 )    NOT NULL ,

8. tncc        INT         NOT NULL ,

9. ncc         VARCHAR( 50 )   NOT NULL ,

10. nccenr        VARCHAR( 50 )   NOT NULL ,

11. PRIMARY KEY ( id_departement )

12. ) tablespace USERS

13. /

15. COMMENT ON TABLE Departements is 'LES DEPARTEMENTS DE FRANCE EN 2013'

16. /

Le programme Perl est bien expliqué, je ne vais donc pas revenir dessus dans le détail.

Le driver utilisé est « dbi:Oracle », ce qui est logique et les fichiers SQL sont analysés afin que le programme crée la requête SQL. Si vous avez des questions, n'hésitez pas à les poser dans la discussion de cet article sur le forum : Commentez .

PrintError => 0 n'est là que pour éviter d'avoir les erreurs affichées (printées) deux fois la première par Oracle la deuxième par « or die ».

AutoCommit => 1 On laisse Oracle faire ses « commit » comme il l'entend, mais en cas de problème un « rollback » explicite n'est pas pris en compte !

AutoCommit => 0 un « rollback » est possible mais doit être explicite, sinon en fin de traitement sans erreur un « commit » implicite est réalisé.

AutoCommit => 0 est préférable, surtout si on a l'habitude de faire un copier/coller de la connexion…

II-C-3 - Interrogation de la base de données

Maintenant que notre base de données et les tables sont prêtes, créons notre deuxième script "GestionRegionFrance.pl" permettant de résoudre notre exercice.

Son but est de :

- lister tous les départements d'une région choisie par l'utilisateur ;

- afficher le nom du département, de la région et le nombre de communes en fonction d'un numéro de département voulu ;

- afficher le nom du département et de la région d'une commune voulue.

Veuillez installer les modules Term::UI et Term::ReadLine qui nous permettrons d'interagir avec la console DOS, Unix, Linux…
Les méthodes fetchrow_array, fetchrow_hashref, selectrow_hashref, selectall_hashref et selectrow_array sont utilisées dans le script. Elles vous seront expliquées ci-dessous.

Examinons progressivement le script.

Dans un premier temps, nous avons besoin de charger les modules nécessaires, puis de nous connecter à notre base de données.

GestionRegionFrance.pl

1. #!/usr/bin/perl

2. #==========================================================================

3. # Auteur : djibril

4. # But     : Interrogation de ma base de données

5. #==========================================================================

6. use warnings;

7. use strict;

9. use DBI;

10. use Term::UI;

11. use Term::ReadLine;

12. use Encode;

13. use utf8;

15. use vars qw/ $VERSION /;    # Version du script

16. $VERSION = '1.0';

18. my $encodage = ActiverAccents();

20. # Paramètres de connection à la base de données

21. my $bd        = 'France2013';

22. my $serveur    = 'localhost';      # Il est possible de mettre une adresse IP

23. my $identifiant = 'root';      # identifiant

24. my $motdepasse    = '';

25. my $port    = '';

27. # Connection à la base de données mysql

28. print "Connexion à la base de données $bd\n";

29. my $dbh = DBI->connect( "DBI:mysql:database=$bd;host=$serveur;port=$port",

30. $identifiant, $motdepasse, {

31. RaiseError => 1,

32. }

33. ) or die "Connection impossible à la base de données $bd !\n $! \n $@\n$DBI::errstr";

Le code ci-dessus est semblable au code du premier script. Il nous permet de nous connecter à la base de données. Notez que nous avons chargé les modules Term::UI et Term::ReadLine qui nous permettront de créer une interaction entre le programme et nous à travers la console.

II-C-3-a - Lister tous les départements d'une région

Nous souhaitons afficher tous les départements d'une région de notre choix. Afin de rendre notre programme plus interactif, ce dernier nous proposera une liste de différentes régions. On pourra ainsi effectuer notre choix.

Dans un premier temps, créons une procédure afin de récupérer dans notre base de données toutes les régions de France.

1. # Procédure pour obtenir toutes les régions de France - méthode fetchrow_array

2. sub obtenir_region_france {

3. my $dbh = shift;

5. my @les_regions_france;

6. my $prep = $dbh->prepare('SELECT ncc FROM Regions ORDER BY ncc') or die $dbh->errstr;

7. $prep->execute() or die "Echec requ&#234;te\n";

8. while ( my ($region) = $prep->fetchrow_array ) {

9. push( @les_regions_france, $region );

10. }

11. $prep->finish();

12. print "\n";

14. return @les_regions_france;

15. }

Cette procédure récupère en argument l'objet DBI et utilise les méthodes classiques pour faire un SELECT. Il s'agit des méthodes prepare, execute, fetchXXX_YYY et finish.
Notez qu'il est possible d'utiliser d'autres méthodes qui permettent d'écrire moins de code, nous en parlerons plus tard.

- la méthode prepare permet à DBI de préparer la requête SQL pour une exécution ultérieure et nous retourne un descripteur d'instruction que nous utiliserons par la suite (ligne 6) ;

- la méthode execute effectue le traitement nécessaire pour exécuter l'instruction préparée ;

- la méthode fetchrow_array récupère une ligne de données et retourne une liste contenant les valeurs de champ (ligne 8).

Pense-bête de fetchrow_array :

- fetch => récupérer ;

- row => ligne ;

- array => tableau.

Dans notre cas, nous nous attendons à plusieurs lignes de résultats (plusieurs régions), d'où l'utilisation de la boucle while. Tant qu'il y aura une ligne de résultat, Perl restera dans le while.
Notre requête SQL ne sélectionne qu'un seul champ (ncc), donc notre tableau n'aura qu'une seule case.

Ligne 8

1. while ( my ($region) = $prep->fetchrow_array ) {

Les régions sont stockées dans la liste @les_regions_france, ensuite, nous fermons la requête grâce à la méthode finish.

Maintenant que nous avons la liste des régions de France, créons une interaction entre le programme et nous par l'intermédiaire de l'utilisation du module Term::UI. Nous aurions pu utiliser <STDIN> mais le module nous facilite la vie. Voici le code :

1. #===========================================

2. # Lister tous les départements d'une région

3. #===========================================

4. # 1 - Récupération de toutes les régions de France

5. my @regions_france = obtenir_region_france($dbh);

7. # 2 - Choix de l'utilisateur

8. my $term           = Term::ReadLine->new('brand');

9. my $nom_region_choisie = $term->get_reply(

10. print_me => "1- Listons tous les départements d'une région",

11. prompt   => encode($encodage,'Choisissez une région de France : '),

12. choices  => \@regions_france,

13. default  => 'PICARDIE',

14. );

16. # 3 - Récupération de tous les départements - méthode fetchrow_hashref

17. afficher_departement_dune_region( $dbh, $nom_region_choisie );

La méthode get_reply du module Term::ReadLine nous permet de poser une question dans la console en proposant une liste de choix (nos régions de France) grâce à l'option choices et en donnant une sélection par défaut (default).
Nous obtenons ceci :

Tous les départements d'une région

1. 1- Listons tous les départements d'une région

2. 1> ALSACE

3. 2> AQUITAINE

4. 3> AUVERGNE

5. 4> BASSE-NORMANDIE

6. 5> BOURGOGNE

7. 6> BRETAGNE

8. 7> CENTRE

9. 8> CHAMPAGNE-ARDENNE

10. 9> CORSE

11. 10> FRANCHE-COMTE

12. 11> GUADELOUPE

13. 12> GUYANE

14. 13> HAUTE-NORMANDIE

15. 14> ILE-DE-FRANCE

16. 15> LA REUNION

17. 16> LANGUEDOC-ROUSSILLON

18. 17> LIMOUSIN

19. 18> LORRAINE

20. 19> MARTINIQUE

21. 20> MAYOTTE

22. 21> MIDI-PYRENEES

23. 22> NORD-PAS-DE-CALAIS

24. 23> PAYS DE LA LOIRE

25. 24> PICARDIE

26. 25> POITOU-CHARENTES

27. 26> PROVENCE-ALPES-COTE D'AZUR

28. 27> RHONE-ALPES

30. Choisissez une région de France :  [24]:

Une fois notre choix effectué, nous utiliserons cette région pour lister les départements à partir de la procédure afficher_departement_dune_region suivante :

1. # Procédure pour afficher les départements d'une région

2. sub afficher_departement_dune_region {

3. my ( $dbh, $nom_region_choisie ) = @_;

5. my $requete_departement_cheflieu = <<"SQL";

6. SELECT Departements.nccenr as NomDep, Departements.cheflieu as cheflieu

7. FROM Departements

8. INNER JOIN Regions ON Regions.id_region = Departements.id_region

9. WHERE Regions.ncc = "$nom_region_choisie"

10. SQL

11. my $prep = $dbh->prepare($requete_departement_cheflieu) or die $dbh->errstr;

12. $prep->execute() or die "Echec requ&#234;te : $requete_departement_cheflieu\n";

14. print "La région $nom_region_choisie possède ", $prep->rows, " département(s)\n";

15. while ( my $ref_donnees = $prep->fetchrow_hashref ) {

16. print "\t- $ref_donnees->{NomDep}, chef-lieu $ref_donnees->{cheflieu}\n";

17. }

18. $prep->finish();

19. print "\n";

20. return;

21. }

Cette procédure nous permet d'utiliser fetchrow_hashref à la place de fetchrow_array

Pense-bête :

- fetch => récupérer ;

- row => ligne ;

- hashref => référence de hash.

Ligne 15

1. while ( my $ref_donnees = $prep->fetchrow_hashref ) {

Chaque ligne de résultat est retournée sous forme de référence de hash au lieu de liste comme précédemment.
Pour accéder à la valeur de chaque champ, il suffit de passer à notre référence la clé qui correspondant au nom de chaque champ spécifié dans notre requête SQL (NomDep et cheflieu) :

1. SELECT Departements.nccenr as NomDep, Departements.cheflieu as cheflieu

2. FROM Departements

3. INNER JOIN Regions ON Regions.id_region = Departements.id_region

4. WHERE Regions.ncc = "$nom_region_choisie"

D'où en ligne 16 : $ref_donnees->{NomDep} et $ref_donnees->{cheflieu}.

Si vous avez des difficultés à comprendre la notion de référence, lisez la FAQ , section :Les références.

En choisissant la région ILE-DE-FRANCE (14), nous obtenons :

Départements d'ile de France

1. Choisissez une région de France :    [23]: 14

2. La région ILE-DE-FRANCE possède 8 département(s)

3. - Paris, chef-lieu 75056

4. - Seine-et-Marne, chef-lieu 77288

5. - Yvelines, chef-lieu 78646

6. - Essonne, chef-lieu 91228

7. - Hauts-de-Seine, chef-lieu 92050

8. - Seine-Saint-Denis, chef-lieu 93008

9. - Val-de-Marne, chef-lieu 94028

10. - Val-d'Oise, chef-lieu 95500

Ouf, la première question de notre exercice est terminée ! J'espère que vous êtes encore en forme pour continuer  !

II-C-3-b - Afficher le nom du département, de la région et le nombre de communes en fonction d'un numéro de département

Maintenant, nous n'utiliserons plus les méthodes fetchXXX_YYY, mais les méthodes selectXXX_YYY. Pour ce faire, procédons comme ci-dessus en créant une interaction et une procédure pour cet affichage (afficher_departement_dune_region).

1. # 4- Afficher le nom du département, de la région et le nombre de

2. # communes en fonction d'un numéro de département - méthode selectrow_array,

3. my $numero_departement = $term->get_reply(

4. print_me =>

5. "2- Trouvons le nom d'un département, de la région et le nombre de communes à partir d'un numéro de département",

6. prompt  => encode($encodage,'Donnez un numéro de département : '),

7. default => 75,

8. );

10. afficher_informations_dun_departement( $dbh, $numero_departement );

1. # Procédure pour afficher toutes les informations d'un numéro de département

2. sub afficher_informations_dun_departement {

3. my ( $dbh, $numero_departement ) = @_;

5. my $requete_dep_cheflieu_region = <<"SQL";

6. SELECT

7. Departements.nccenr   AS NomDep,

8. Departements.cheflieu AS cheflieu,

9. Regions.ncc         AS NomRegion

10. FROM Departements

11. INNER JOIN Regions ON Regions.id_region = Departements.id_region

12. WHERE Departements.id_departement = '$numero_departement'

13. SQL

14. my $requete_nombre_commune = <<"SQL";

15. SELECT COUNT( id_communes ) as NbrCommunes

16. FROM communes

17. WHERE id_departement = "$numero_departement"

18. SQL

19. my ( $nom_departement, $nom_cheflieu, $nom_region ) = $dbh->selectrow_array($requete_dep_cheflieu_region);

21. if ( defined $nom_cheflieu ) {

22. print "\t - Numéro du département : $numero_departement\n";

23. print "\t - Nom du département : $nom_departement\n";

24. print "\t - Nom du chef-lieu : $nom_cheflieu\n";

25. print "\t - Nom de la région : $nom_region\n";

27. # Calculer le nombre de communes

28. my ($ref_commune) = $dbh->selectrow_hashref($requete_nombre_commune);

29. print "\t - Nombre de communes : ", $ref_commune->{NbrCommunes}, "\n\n";

30. }

31. else {

32. print "Numéro de département inconnu\n";

33. }

35. return;

36. }

Dans le code ci-dessus, nous utilisons les méthodes selectrow_array et selectrow_hashref pour récupérer le nom de la région, du département et le nombre de communes pour le numéro de département saisi par l'utilisateur.
Ah !! Je vais donc vous expliquer comment écrire moins de code  !

Pense-bête :

- select => sélectionne ;

- row => ligne ;

- hashref => référence de hash ;

- array => tableau.

En fait, les méthodes de type selectXXX_YYY combinent les méthodes prepare, execute et fetchXXX_YYY.

Comparaison entre fetch et select

select

fetch

selectrow_array

combine prepare, execute et fetchrow_array

selectrow_arrayref

combine prepare, execute et fetchrow_arrayref

selectrow_hashref

combine prepare, execute et fetchrow_hashref

- Avantage :

La combinaison de trois méthodes permet de densifier le code. Par exemple :

ligne 19

1. my ( $nom_departement, $nom_cheflieu, $nom_region ) =

2. $dbh->selectrow_array($requete_dep_cheflieu_region);

Ici, nous récupérons un tableau contenant trois cases en une seule ligne, via la méthode selectrow_array. Alors qu'ici :

ligne 28

1. my ($ref_commune) = $dbh->selectrow_hashref($requete_nombre_commune);

nous récupérons une référence de hash grâce à la méthode selectrow_hashref.

Je vous conseille d'utiliser les méthodes selectrow_YYY lorsque vous souhaitez récupérer une seule ligne de résultat.

Exemple de résultat :

1. Donnez un numéro de département :  [75]: 48

2. - Numéro du département : 48

3. - Nom du département : Lozère

4. - Nom du chef-lieu : 48095

5. - Nom de la région : LANGUEDOC-ROUSSILLON

6. - Nombre de communes : 185

II-C-3-c - Trouver le nom du département et de la région d'une commune donnée

Maintenant, nous utiliserons la méthode selectall_YYY. Pour ce faire, procédons comme ci-dessus en créant une interaction et une procédure pour cet affichage (afficher_informations_dune_commune).

1. # 5- Trouver le nom du département et de la région d'une commune donnée

2. my $commune = $term->get_reply(

3. print_me => "3- Trouvons le nom du département et de la région d'une commune",

4. prompt   => "Nom d'une commune : ",

5. default  => 'glandage',

6. );

8. # Les noms des communes (ncc) sont en majuscules dans la base

9. $commune = uc $commune;

10. # Les espaces dans les noms des communes sont remplacés par un tiret dans la base

11. $commune =~ s{\s}{-}g;

12. afficher_informations_dune_commune( $dbh, $commune );

14. # Déconnexion de la base de données

15. $dbh->disconnect();

1. # Procédure pour afficher toutes les informations d'une commune

2. sub afficher_informations_dune_commune {

3. my ( $dbh, $commune ) = @_;

5. my $requete_commune = <<"SQL";

6. SELECT

7. Departements.id_departement    AS id_departement,

8. Departements.nccenr        AS NomDep,

9. Departements.cheflieu        AS cheflieu,

10. Regions.ncc            AS NomRegion,

11. Communes.ncc            AS commune

12. FROM Communes

13. INNER JOIN Regions ON Regions.id_region = Communes.id_region

14. INNER JOIN Departements ON Departements.id_departement = Communes.id_departement

15. WHERE Communes.ncc LIKE "%$commune%"

16. SQL

18. my $hash_ref_donnee = $dbh->selectall_hashref($requete_commune, 'id_departement');

19. foreach my $id_dep ( sort { $a <=> $b } keys %{$hash_ref_donnee} ) {

20. print "\t - Nom de la commune : $hash_ref_donnee->{$id_dep}{commune}\n";

21. print "\t - Nom du département : $hash_ref_donnee->{$id_dep}{NomDep}\n";

22. print "\t - Nom du chef-lieu : $hash_ref_donnee->{$id_dep}{cheflieu}\n";

23. print "\t - Nom de la région : $hash_ref_donnee->{$id_dep}{NomRegion}\n\n\n";

24. }

26. return;

27. }

Dans le code ci-dessus, nous utilisons la méthode selectall_hashref pour récupérer le nom du département, de la région, le chef-lieu pour une commune saisie par l'utilisateur.

Pense-bête :

- select => sélectionne ;

- all => toutes les lignes ;

- hashref => référence de hash ;

En fait, les méthodes de type selectall_YYY combinent les méthodes prepare, execute et fetchall_YYY.

Comparaison entre fetch et select

select

fetch

selectall_arrayref

combine prepare, execute et fetchall_arrayref

selectall_hashref

combine prepare, execute et fetchall_hashref

select_all_hashref renvoie une référence de hash (hashref) qui contient toutes les lignes de résultats. Chaque ligne est identifiable par une clé correspondant à la valeur du champ que nous avons spécifié (généralement un champ dont les valeurs sont uniques) et en valeur une référence de hash avec pour clé le nom du champ et en valeur la donnée.

1. my $hash_ref_donnee = $dbh->selectall_hashref($requete_commune, 'id_departement');

Ici, nous précisons que la clé qui identifiera chaque ligne de résultat correspondra à la valeur de l'identifiant de département (nous savons qu'elle est unique à chaque ligne de résultat dans notre table). Le choix de la clé est important sous peine d'écraser les informations dans le hash et avoir une incohérence de résultat. Nous choisissons également id_departement car nous l'avons sélectionné dans notre requête SQL. Donc faites attention !!

Ensuite, il faut parcourir ce hash pour afficher les informations.

1. my $hash_ref_donnee = $dbh->selectall_hashref($requete_commune, 'id_departement');

2. foreach my $id_dep ( sort { $a <=> $b } keys %{$hash_ref_donnee} ) {

3. print "\t - Nom de la commune : $hash_ref_donnee->{$id_dep}{commune}\n";

4. print "\t - Nom du département : $hash_ref_donnee->{$id_dep}{NomDep}\n";

5. print "\t - Nom du chef-lieu : $hash_ref_donnee->{$id_dep}{cheflieu}\n";

6. print "\t - Nom de la région : $hash_ref_donnee->{$id_dep}{NomRegion}\n\n\n";

7. }

Avantage :

- c'est donc une façon élégante de récupérer les résultats d'une requête ;

- en terme de lisibilité et de maintenance, on y gagne grandement ;

- il n'est pas nécessaire d'utiliser la méthode finish, DBI le gérera pour nous.

Inconvénient :

- il ne faut pas les utiliser si notre requête génère beaucoup de données, car tout sera en mémoire dans le hash ou array ;

- selectall_hashref permet d'avoir un champ à utiliser comme clé. Il faut donc bien vérifier que les valeurs de ce champ sont uniques pour éviter de mauvaises surprises ;

- il faut bien maîtriser l'utilisation des références pour s'y retrouver. En soi, ce n'est pas vraiment un inconvénient car c'est plutôt utile en Perl !!

Exemple de résultat :

1. Nom d'une commune :  [glandage]:

2. - Nom de la commune : GLANDAGE

3. - Nom du département : Drôme

4. - Nom du chef-lieu : 26362

5. - Nom de la région : RHONE-ALPES

II-C-4 - Exemple sous Oracle

Pour que le programme ci-dessus fonctionne sous Oracle, il faut quelques modifications :

- Oracle renvoie les noms des colonnes en MAJUSCULES ce qui implique les selectrow_hashref.
Par exemple : $ref_commune->{'NBRCOMMUNES'} au lieu de $ref_commune->{NbrCommunes} ainsi que dans les clauses

1. AS SELECT COUNT( id_communes ) as NBRCOMMUNES ;

- Les clauses LIKE avec point d'interrogation « ? » on étaient remplacées par l'utilisation de la méthode bind_columns ($sth->bind_columns). Ce n'est pas obligatoire mais cela montre une autre façon d'écrire.

- Les clauses JOIN dans les requêtes ont été supprimées pour une autre écriture. C'est le choix de dmganges par habitude  !

Voici le programme qui sera téléchargeable ci-dessous :

OracleGestionRegionFrance.pl

1. #!/usr/bin/perl

2. #==========================================================================

3. # Auteur : djibril

4. # But     : Création des tables SQL et insertion de données

5. #

6. # http://djibril.developpez.com/tutoriels/perl/perl-dbi/

7. #

8. # Quelques modifs mineures par dmganges pour Oracle :

9. # - Connexion à BDD

10. # - Oracle renvoie les noms des colonnes en MAJUSCULES ce qui implique

11. #     dans les selectrow_hashref par ex :

12. #         $ref_commune->{'NBRCOMMUNES'} au lieu de $ref_commune->{NbrCommunes}

13. #   Ainsi que dand les clause AS

14. #         SELECT COUNT( id_communes ) as NBRCOMMUNES

15. #    - Modif des clauses LIKE avec ? pour méthode $sth->bind_columns

16. #==========================================================================

17. use warnings;

18. use strict;

19. use utf8;

20. use DBI;                      # Charge le module DBI

21. use DBI qw(:sql_types);               # Pour utiliser les types du genre SQL_VARCHAR

22. use Term::UI;                      # Pour interaction avec la console

23. use Term::ReadLine;                  # Pour interaction avec la console

25. use vars qw/ $VERSION /;              # Version du script

26. $VERSION = '1.0';

28. ActiverAccents();

30. # Paramètres de connexion à la base de données

31. my $host = "localhost";

32. my $port = "1521";

33. my $bdd  = "XE";

34. my $user = "michel";

35. my $pass = "michel";

37. my $dbh = DBI->connect("dbi:Oracle:host=$host;port=$port;sid=$bdd", $user, $pass, {

38. PrintError => 0,

39. AutoCommit => 0

40. }) or die "\nERR=Connexion impossible à la base de données $bdd\n $! \n $@\n$DBI::errstr";

42. my ($Sysdate) = $dbh->selectrow_array("SELECT sysdate FROM dual")

43. or die "\nERR=Sysdate\n $! \n $@\n$DBI::errstr";

44. print "Base OK Date = $Sysdate\n\n";

46. # 1 - Récupération de toutes les régions de France

47. my @Regions = &obtenir_region_france($dbh);

48. foreach my $Region ( @Regions ) {

49. print "$Region\n";

50. }

52. #===========================================

53. # Lister tous les départements d'une région

54. #===========================================

55. # 2 - Choix de l'utilisateur

56. my $term           = Term::ReadLine->new('brand');

57. my $nom_region_choisie = $term->get_reply(

58. print_me => "1- Listons tous les départements d'une région",

59. prompt   => "Choisissez une r\x82gion de France : ",

60. choices  => \@Regions,

61. default  => 'PICARDIE',

62. );

64. # 3 - Récupération de tous les départements - méthode $sth->bind_columns

65. afficher_departement_dune_region( $dbh, $nom_region_choisie );

67. # 4- Afficher le nom du département, de la région et le nombre de

68. # communes en fonction d'un numéro de département - méthode selectrow_array

69. # nombre de communes - méthode selectrow_hashref

70. my $numero_departement = $term->get_reply(

71. print_me =>

72. "\n2- Trouvons le nom d'un département, de la région et le nombre de communes à partir d'un numéro de département",

73. prompt  => "Donnez un num\x82ro de d\x82partement  :",

74. default => 75,

75. );

77. afficher_informations_dun_departement( $dbh, $numero_departement );

79. # 5- Trouver le nom du département et de la région d'une commune donnée

80. my $commune = $term->get_reply(

81. print_me => "\n3- Trouvons le nom du département et de la région d'une commune",

82. prompt   => "Nom d'une commune : ",

83. default  => 'GANGE',

84. );

86. # Les noms des communes (ncc) sont en majuscules dans la base

87. $commune = uc $commune;

88. # Les espaces dans les noms des communes sont remplacés par un tiret dans la base

89. $commune =~ s{\s}{-}g;

90. afficher_informations_dune_commune( $dbh, $commune );

92. print "\n\nFin consultation\n";

93. $dbh->disconnect() or die "\nERR=disconnect\n $! \n $@\n$DBI::errstr";

95. ##############################################################################

96. # Procédure pour obtenir toutes les régions de France - méthode fetchrow_array

97. sub obtenir_region_france {

98. my $dbh = shift;

99. my @les_regions_france;

100. my $sth = $dbh->prepare('SELECT ncc FROM Regions ORDER BY ncc')

101. or die "\nERR=dbh->prepare\n $! \n $@\n$DBI::errstr";

102. $sth->execute() or die "\nERR=execute\n $! \n $@\n$DBI::errstr";

103. while ( my ($region) = $sth->fetchrow_array ) {

104. push( @les_regions_france, $region );

105. }

106. $sth->finish() or die "\nERR=sth->finish\n $! \n $@\n$DBI::errstr";

107. print "\n";

108. return @les_regions_france;

109. }

111. # Procédure pour afficher les départements d'une région

112. # Modifiée :

113. # - use DBI qw(:sql_types) Pour utiliser les types du genre SQL_VARCHAR

114. # - autre fa&#231;on de construire la requ&#234;te

115. # - suppression des clauses AS

116. # - passage d'un paramètre avec $sth->bind_param

117. # - récupération des colonnes dans l'ordre avec $sth->bind_columns directement dans my( $NomDep, $ChefLieu )

119. sub afficher_departement_dune_region {

120. my ( $dbh, $nom_region_choisie ) = @_;

121. my $Sql = qq{

122. SELECT departements.nccenr, departements.cheflieu

123. FROM departements, regions

124. WHERE regions.id_region = departements.id_region

125. AND regions.ncc LIKE ?

126. };

128. my $sth = $dbh->prepare($Sql) or die "\nERR=dbh->prepare\n $! \n $@\n$DBI::errstr";

129. $sth->bind_param( 1, $nom_region_choisie, SQL_VARCHAR );

130. my $rv = $sth->execute() or die "\nERR=execute\n $! \n $@\n$DBI::errstr";

132. my( $NomDep, $ChefLieu );

133. $sth->bind_columns( \$NomDep, \$ChefLieu ) or die "\nERR=sth->bind_columns\n $! \n $@\n$DBI::errstr";

134. print "\n";

135. while( $sth->fetch() ) {

136. print (sprintf ( "%20s %8s \n", $NomDep, $ChefLieu ));

137. }

138. print "\nFIN\n";

139. $sth->finish() or die "\nERR=sth->finish\n $! \n $@\n$DBI::errstr";

140. return;

141. }

143. # Procédure pour afficher toutes les informations d'un numéro de département

144. sub afficher_informations_dun_departement {

145. my ( $dbh, $numero_departement ) = @_;

146. my $requete_dep_cheflieu_region = <<"SQL";

147. SELECT

148. Departements.nccenr   AS NomDep,

149. Departements.cheflieu AS cheflieu,

150. Regions.ncc       AS NomRegion

151. FROM Departements

152. INNER JOIN Regions ON Regions.id_region = Departements.id_region

153. WHERE Departements.id_departement = '$numero_departement'

154. SQL

156. my $requete_nombre_commune = <<"SQL";

157. SELECT COUNT(id_communes) as NbrCommunes

158. FROM communes

159. WHERE id_departement = '$numero_departement'

160. SQL

162. my ( $nom_departement, $nom_cheflieu, $nom_region ) = $dbh->selectrow_array($requete_dep_cheflieu_region);

163. print "\n";

164. if ( defined $nom_cheflieu ) {

165. print "\t - Numéro du département : $numero_departement\n";

166. print "\t - Nom du département      : $nom_departement\n";

167. print "\t - Nom du chef-lieu      : $nom_cheflieu\n";

168. print "\t - Nom de la région      : $nom_region\n";

170. # Calculer le nombre de communes

171. # Nb Oracle renvoie les noms des colonnes en MAJUSCULES

172. my ($ref_commune) = $dbh->selectrow_hashref($requete_nombre_commune) or die $dbh->errstr;

173. print "\n\t - Nombre de communes    : ", $ref_commune->{'NBRCOMMUNES'}, "\n\n";

175. # Ou, si on ne fait pas as NbrCommunes :

176. # print "\t - Nombre de communes : ", $ref_commune->{'COUNT(ID_COMMUNES)'}, "\n\n";

178. # Ou avec selectrow_array

179. # my ($ref_commune) = $dbh->selectrow_array($requete_nombre_commune);

180. # print "\n\t - Nombre de communes    : $ref_commune\n\n";

181. } else {

182. print "\nNuméro de département inconnu\n";

183. }

184. print "\nFIN\n";

185. return;

186. }

188. # Procédure pour afficher toutes les informations d'une commune

189. sub afficher_informations_dune_commune {

190. my ( $dbh, $commune ) = @_;

191. =pod

192. my $requete_commune = <<"SQL";

193. SELECT

194. Departements.id_departement    AS id_departement,

195. Departements.nccenr        AS NomDep,

196. Departements.cheflieu        AS cheflieu,

197. Regions.ncc            AS NomRegion,

198. Communes.ncc            AS commune

199. FROM Communes

200. INNER JOIN Regions ON Regions.id_region = Communes.id_region

201. INNER JOIN Departements ON Departements.id_departement = Communes.id_departement

202. WHERE Communes.ncc LIKE '%$commune%'

203. SQL

204. =cut

206. my $requete_commune = <<"SQL";

207. SELECT

208. Departements.id_departement    AS id_departement,

209. a.ncc               AS commune,

210. Departements.nccenr        AS NomDep,

211. Departements.cheflieu       AS cheflieu,

212. b.ncc               AS NomVille,

213. Regions.ncc            AS NomRegion

214. FROM Departements, Regions, Communes a, Communes b

215. WHERE a.id_departement = b.id_departement

216. AND b.com = TO_NUMBER(SUBSTR(Departements.cheflieu,3))

217. AND Regions.id_region = a.id_region

218. AND Departements.id_departement = a.id_departement

219. AND a.ncc LIKE '%$commune%'

220. SQL

222. # NB ID_DEPARTEMENT en MAJUSCULES, ainsi que tous les $hash_ref_donnee->{$id_dep}{}

223. my $hash_ref_donnee = $dbh->selectall_hashref($requete_commune, 'ID_DEPARTEMENT')

224. or die "\nERR=dbh->selectall_hashref\n $! \n $@\n$DBI::errstr";

225. foreach my $id_dep ( sort { $a <=> $b } keys %{$hash_ref_donnee} ) {

226. print "\t - Nom de la commune           : $hash_ref_donnee->{$id_dep}{COMMUNE}\n";

227. print "\t - Nom du département           : $hash_ref_donnee->{$id_dep}{NOMDEP}\n";

228. print "\t - Ville du chef-lieu dept & code : $hash_ref_donnee->{$id_dep}{NOMVILLE} \t $hash_ref_donnee->{$id_dep}{CHEFLIEU} \n";

229. print "\t - Nom de la région           : $hash_ref_donnee->{$id_dep}{NOMREGION}\n\n\n";

230. }

231. return;

232. }

234. #==============================================================

235. # Pour avoir les accents sur la console DOS ou non

236. # http://perl.developpez.com/faq/perl/?page=Terminal#Accents

237. #==============================================================

238. sub ActiverAccents {

239. my $encodage;

240. # Windows

241. if ( lc($^O ) eq 'mswin32') {

242. eval {

243. my ($codepage) = ( `chcp` =~ m/:\s+(\d+)/ );

244. $encodage = "cp$codepage";

245. foreach my $h ( \*STDOUT, \*STDERR, \*STDIN, ) {

246. binmode $h, ":encoding($encodage)";

247. }

248. };

249. }

250. else {

251. $encodage = `locale charmap`;

252. eval {

253. foreach my $h ( \*STDOUT, \*STDERR, \*STDIN, ) {

254. binmode $h, ":encoding($encodage)";

255. }

256. };

257. }

258. return $encodage;

259. }

261. #The following conventions are used in this document:

262. #

263. #  $dbh    Database handle object

264. #  $sth    Statement handle object

265. #  $drh    Driver handle object (rarely seen or used in applications)

266. #  $h       Any of the handle types above ($dbh, $sth, or $drh)

267. #  $rc       General Return Code    (boolean: true=ok, false=error)

268. #  $rv       General Return Value (typically an integer)

269. #  @ary    List of values returned from the database, typically a row of data

270. #  $rows   Number of rows processed (if available, else -1)

271. #  $fh       A filehandle

272. #  undef   NULL values are represented by undefined values in Perl

273. #  \%attr  Reference to a hash of attribute values passed to methods

PrintError => 0 n'est là que pour éviter d'avoir les erreurs affichées (printées) deux fois la première par Oracle la deuxième par « or die ».

AutoCommit => 1 On laisse Oracle faire ses « commit » comme il l'entend, mais en cas de problème un « rollback » explicite n'est pas pris en compte !

AutoCommit => 0 un « rollback » est possible mais doit être explicite, sinon en fin de traitement sans erreur un « commit » implicite est réalisé.

AutoCommit => 0 est préférable, surtout si on a l'habitude de faire un copier/coller de la connexion…

II-C-5 - Téléchargement des programmes

Vous trouverez ici quatre programmes, trois fichiers de l'INSEE et les trois fichiers SQL utiles.pour les programmes Oracle pour résoudre l'exercice.
Je tiens à préciser que je n'ai pas testé les programmes pour la partie Oracle Si vous constatez une anomalie ou amélioration, n'hésitez pas à nous en faire part. Commentez

III - Liens

Liens utiles pour compléter vos connaissances :

- moduleDBI ;

- site officiel de Perl DBI ;

- des cours SQL ;

- des cours SGBD ;

- MySQL ;

- PostgreSQL ;

- EasyPHP ;

- installation des modules Perl ;

- INSEE ;

- Term::UI ;

- Les références.

IV - Conclusion

Avant toute chose, pensez à écrire correctement vos requêtes SQL ! Testez-les en console ou via les logiciels comme phpMyAdmin ou phpPgAdmin. Choisissez correctement vos méthodes DBI. Lisez la documentation CPAN de DBI, vous y trouverez d'autres méthodes intéressantes comme COMMIT. Cette dernière permet de protéger vos transferts de données en cas d'arrêt brutal du serveur pour une raison quelconque.
Profitez des cours SQL et Perl qui sont sur ce site et n'oubliez pas qu'il y a aussi les forums pour vous aider !

N.B. : Ces scripts ont été testés sous MySQL et sous PostgreSQL.
En ce qui concerne Oracle, je ne sais pas s'il y a des modifications à prévoir dans les codes Perl en dehors de la connexion à la base de données. Faites-moi un retour si nécessaire.

J'espère que cet article vous a aidé à comprendre l'utilisation du module DBI pour interagir avec les bases de données en Perl.

N'hésitez pas à faire des remarques, corrections ou appréciations. Commentez

V - Remerciements

Je remercie dmganges pour les remarques et sa contribution pour les exemples de programmes Oracle.
Je remercie également ClaudeLELOUP et stoyak pour la relecture de ce tutoriel.